ESP32 - Joystick - Servo Motor
Neste tutorial, vamos aprender a usar o ESP32 e um joystick para controlar dois servo motores ou um kit pan-tilt com servos.
Um joystick tem dois potenciômetros embutidos, perpendiculares entre si (chamados de eixo X e eixo Y). Esses potenciômetros fornecem valores analógicos (chamados de valor X e valor Y) nos pinos VRX e VRY. Vamos usar esses valores analógicos para controlar dois servo motores de forma independente: o valor X controla o servo #1 e o valor Y controla o servo #2. No caso do kit pan-tilt, o movimento dos dois servo motores cria um movimento em 3-D.
Há dois casos de uso:
- Caso de uso 1: Os servo motores giram de acordo com o movimento da alavanca do joystick:
- Os ângulos dos servo motores são proporcionais ao valor X e ao valor Y do joystick.
- Quando soltamos a alavanca do joystick ⇒ todos os valores voltam para os valores centrais ⇒ os servo motores voltam automaticamente para a posição central
- Caso de uso 2: usar o joystick para comandar os servo motores (comandos para cima/para baixo/esquerda/direita)
- Quando a alavanca do joystick é empurrada para a esquerda, o servo motor #1 se move no sentido horário, passo a passo
- Quando a alavanca do joystick é empurrada para a direita, o servo motor #1 se move no sentido anti-horário, passo a passo
- Quando a alavanca do joystick é empurrada para cima, o servo motor #2 se move no sentido horário, passo a passo
- Quando a alavanca do joystick é empurrada para baixo, o servo motor #2 se move no sentido anti-horário, passo a passo
- Quando soltamos a alavanca do joystick ⇒ os servo motores não voltam para a posição central
- Se o joystick for pressionado (botão de pressão), os servo motores voltam para a posição central
- Como conectar o ESP32 ao joystick e ao servo motor usando protoboard
- Como conectar o ESP32 ao joystick e ao servo motor usando a placa breakout com bornes de parafuso
- Se esta é a primeira vez que você usa o ESP32, veja como configurar o ambiente para o ESP32 na Arduino IDE.
- Conecte o joystick e o servo motor à placa ESP32 conforme o diagrama de ligação acima.
- Conecte a placa ESP32 ao seu PC por meio de um cabo USB Type-C
- Abra a Arduino IDE no seu PC.
- Selecione a placa ESP32 correta (ex.: ESP32 Dev Module) e a porta COM.
- Clique no ícone Libraries na barra esquerda da Arduino IDE.
- Digite ESP32Servo na caixa de pesquisa e procure a biblioteca de servo de Kevin Harrington,John K. Bennett.
- Clique no botão Install para instalar a biblioteca de servo motor para o ESP32.
- Copie o código acima e abra-o com a Arduino IDE
- Clique no botão Upload na Arduino IDE para carregar o código no ESP32
- Abra o Serial Monitor
- Empurre o joystick em alguma direção
- Observe a rotação do servo motor
- Veja o resultado no Serial Monitor
- Clique no ícone Libraries na barra esquerda da Arduino IDE.
- Pesquise “ezButton” e encontre a biblioteca de botão de ArduinoGetStarted.com
- Clique no botão Install para instalar a biblioteca ezButton.
- Copie o código acima e abra-o com a Arduino IDE
- Clique no botão Upload na Arduino IDE para carregar o código no ESP32
- Abra o Serial Monitor
- Empurre o joystick em alguma direção
- Observe a rotação do servo motor
- Veja o resultado no Serial Monitor
- O ADC do ESP32 não é perfeitamente preciso e pode precisar de calibração para dar resultados corretos. Cada placa ESP32 pode ser um pouco diferente, então você precisa calibrar o ADC de cada placa individualmente.
- A calibração pode ser difícil, especialmente para iniciantes, e nem sempre dá exatamente os resultados que você deseja.
Vamos explorar o código dos dois casos de uso nas próximas partes.
Hardware Necessário
Or you can buy the following kits:
| 1 | × | DIYables ESP32 Starter Kit (ESP32 included) | |
| 1 | × | DIYables ESP32 S3 Starter Kit (ESP32 S3 included) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgação: Alguns dos links desta seção são links de afiliado da Amazon. Podemos receber uma comissão pelas compras feitas por meio desses links, sem custo adicional para você. Agradecemos o seu apoio.
Buy Note: For controlling multiple servo motors, use the PCA9685 16 Channel PWM Servo Driver Module to save MCU pins and simplify wiring.
Sobre o Joystick e o Servo Motor
Se você não conhece o joystick e o servo motor (pinagem, como funcionam, como programar...), aprenda sobre eles nos tutoriais a seguir:
Diagrama de Ligação
This image is created using Fritzing. Click to enlarge image
Se você não sabe como alimentar o ESP32 e outros componentes, veja as instruções no tutorial a seguir: Como alimentar o ESP32.
Código ESP32
Código ESP32 - Os servo motores giram de acordo com o movimento da alavanca do joystick
/*
* Este código de ESP32 foi desenvolvido por pt.newbiely.com
* Este código de ESP32 é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/esp32/esp32-joystick-servo-motor
*/
#include <ESP32Servo.h>
#define VRX_PIN 36 // ESP32 pin GPIO36 (ADC0) connected to VRX pin
#define VRY_PIN 39 // ESP32 pin GPIO39 (ADC0) connected to VRY pin
#define SERVO_X_PIN 13 // ESP32 pin GPIO13 connected to Servo motor 1
#define SERVO_Y_PIN 25 // ESP32 pin GPIO25 connected to Servo motor 2
Servo xServo; // create servo object to control a servo 1
Servo yServo; // create servo object to control a servo 2
void setup() {
Serial.begin(9600);
// Set the ADC attenuation to 11 dB (up to ~3.3V input)
analogSetAttenuation(ADC_11db);
xServo.attach(SERVO_X_PIN);
yServo.attach(SERVO_Y_PIN);
}
void loop() {
// read X and Y analog values
int valueX = analogRead(VRX_PIN);
int valueY = analogRead(VRY_PIN);
int xAngle = map(valueX, 0, 4095, 0, 180); // scale it to the servo's angle (0 to 180)
int yAngle = map(valueY, 0, 4095, 0, 180); // scale it to the servo's angle (0 to 180)
xServo.write(xAngle); // rotate servo motor 1
yServo.write(yAngle); // rotate servo motor 2
// print data to Serial Monitor on Arduino IDE
Serial.print("Joystick: ");
Serial.print(valueX);
Serial.print(", ");
Serial.print(valueY);
Serial.print(" => Servo Motor: ");
Serial.print(xAngle);
Serial.print("°, ");
Serial.print(yAngle);
Serial.println("°");
}
Passos Rápidos
8
Serial.println("Hello World!");
Message (Enter to send message to 'ESP32 Dev Module' on 'COM15')
New Line
9600 baud
Coming soon
Você pode ter notado que o servo motor não se move proporcionalmente ao movimento do joystick. Esse problema não é causado pelo joystick nem pelo servo motor em si, mas sim pelo ADC do ESP32. O final deste tutorial explica por que isso acontece.
Código ESP32 - Usar o joystick para comandar os servo motores
/*
* Este código de ESP32 foi desenvolvido por pt.newbiely.com
* Este código de ESP32 é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/esp32/esp32-joystick-servo-motor
*/
#include <ESP32Servo.h>
#include <ezButton.h>
#define VRX_PIN 36 // ESP32 pin GPIO36 (ADC0) connected to VRX pin
#define VRY_PIN 39 // ESP32 pin GPIO39 (ADC0) connected to VRY pin
#define SW_PIN 23 // ESP32 pin GPIO23 connected to SW pin
#define SERVO_X_PIN 13 // ESP32 pin GPIO13 connected to Servo motor 1
#define SERVO_Y_PIN 25 // ESP32 pin GPIO25 connected to Servo motor 2
#define COMMAND_NO 0x00
#define COMMAND_LEFT 0x01
#define COMMAND_RIGHT 0x02
#define COMMAND_UP 0x04
#define COMMAND_DOWN 0x08
#define LEFT_THRESHOLD 1000
#define RIGHT_THRESHOLD 3000
#define UP_THRESHOLD 1000
#define DOWN_THRESHOLD 3000
#define UPDATE_INTERVAL 100 // 100ms
ezButton button(SW_PIN);
Servo xServo; // create servo object to control a servo 1
Servo yServo; // create servo object to control a servo 2
int valueX = 0 ; // to store the X-axis value
int valueY = 0 ; // to store the Y-axis value
int xAngle = 90; // the center position of servo #1
int yAngle = 90; // the center position of servo #2
int command = COMMAND_NO;
unsigned long lastUpdateTime = 0;
void setup() {
Serial.begin(9600);
// Set the ADC attenuation to 11 dB (up to ~3.3V input)
analogSetAttenuation(ADC_11db);
xServo.attach(SERVO_X_PIN);
yServo.attach(SERVO_Y_PIN);
button.setDebounceTime(50); // set debounce time to 50 milliseconds
}
void loop() {
button.loop(); // MUST call the loop() function first
if (millis() - lastUpdateTime > UPDATE_INTERVAL) {
lastUpdateTime = millis() ;
// read X and Y analog values
valueX = analogRead(VRX_PIN);
valueY = analogRead(VRY_PIN);
// converts the analog value to commands
// reset commands
command = COMMAND_NO;
// check left/right commands
if (valueX < LEFT_THRESHOLD)
command = command | COMMAND_LEFT;
else if (valueX > RIGHT_THRESHOLD)
command = command | COMMAND_RIGHT;
// check up/down commands
if (valueY < UP_THRESHOLD)
command = command | COMMAND_UP;
else if (valueY > DOWN_THRESHOLD)
command = command | COMMAND_DOWN;
// NOTE: AT A TIME, THERE MAY BE NO COMMAND, ONE COMMAND OR TWO COMMANDS
// print command to serial and process command
if (command & COMMAND_LEFT) {
Serial.println("COMMAND LEFT");
xAngle--;
}
if (command & COMMAND_RIGHT) {
Serial.println("COMMAND RIGHT");
xAngle++;
}
if (command & COMMAND_UP) {
Serial.println("COMMAND UP");
yAngle--;
}
if (command & COMMAND_DOWN) {
Serial.println("COMMAND DOWN");
yAngle++;
}
}
if (button.isPressed()) {
Serial.println("The button is pressed");
xAngle = 90; // the center position of servo #1
yAngle = 90; // the center position of servo #2
}
xServo.write(xAngle); // rotate servo motor 1
yServo.write(yAngle); // rotate servo motor 2
// print data to Serial Monitor on Arduino IDE
Serial.print("Servo Motor's Angle: ");
Serial.print(xAngle);
Serial.print("°, ");
Serial.print(xAngle);
Serial.println("°");
}
Passos Rápidos
8
Serial.println("Hello World!");
Message (Enter to send message to 'ESP32 Dev Module' on 'COM15')
New Line
9600 baud
Explicação do Código
Leia a explicação linha por linha nas linhas de comentário do código-fonte!
※ Nota:
Este tutorial usa a função analogRead() para ler valores de um ADC (Conversor Analógico-Digital) conectado a um joystick. O ADC do ESP32 é bom para projetos que NÃO precisam de alta precisão. No entanto, para projetos que precisam de medições precisas, observe:
Para projetos que precisam de alta precisão, considere usar um ADC externo (ex.: ADS1115) com o ESP32 ou usar um Arduino, que tem um ADC mais confiável. Se você ainda quiser calibrar o ADC do ESP32, consulte o ESP32 ADC Calibration Driver