ESP32 - Sistema de Trava de Porta com Senha
Este tutorial ensina como usar o ESP32, um teclado e uma fechadura eletromagnética para criar um sistema de trava de porta. Os usuários serão solicitados a digitar a senha pelo teclado. Se a senha for válida, o ESP32 controla a fechadura eletromagnética para destrancar a porta. O tutorial também adiciona, opcionalmente, um LCD para mais conveniência. O código ESP32 também suporta várias senhas.
Hardware Necessário
Or you can buy the following kits:
| 1 | × | DIYables ESP32 Starter Kit (ESP32 included) | |
| 1 | × | DIYables ESP32 S3 Starter Kit (ESP32 S3 included) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgação: Alguns dos links desta seção são links de afiliado da Amazon. Podemos receber uma comissão pelas compras feitas por meio desses links, sem custo adicional para você. Agradecemos o seu apoio.
Nota de compra: A maioria dos displays LCD I2C no mercado é de 5V. Eles podem funcionar com esta placa, mas não é seguro e pode danificar a placa. Recomendamos fortemente usar o display LCD I2C de 3.3V recomendado acima.
Sobre o Teclado, a Fechadura Eletromagnética e o LCD
Temos tutoriais específicos sobre teclado, fechadura eletromagnética e LCD. Cada tutorial contém informações detalhadas e instruções passo a passo sobre a pinagem do hardware, o princípio de funcionamento, a ligação ao ESP32, o código ESP32... Saiba mais sobre eles nos links a seguir:
Como verificar a senha
- Uma tecla especial * é usada para redefinir a senha
- Uma tecla especial # é usada para finalizar a digitação da senha.
- Cada tecla digitada, exceto * e #, é adicionada a uma string.
- Quando a tecla # é pressionada, a digitação da senha é concluída. O ESP32 compara a string digitada com as senhas predefinidas.
- Se a senha digitada for válida, a porta é destrancada.
Diagrama de Ligação
This image is created using Fritzing. Click to enlarge image
Se você não sabe como alimentar o ESP32 e outros componentes, veja as instruções no tutorial a seguir: Como alimentar o ESP32.
Código ESP32 - Sistema de trava de porta com senha usando teclado e fechadura eletromagnética
/*
* Este código de ESP32 foi desenvolvido por pt.newbiely.com
* Este código de ESP32 é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/esp32/esp32-door-lock-system-using-password
*/
#include <Keypad.h>
#define RELAY_PIN 19 // ESP32 pin GPIO19 connected to the relay
#define ROW_NUM 4 // keypad four rows
#define COLUMN_NUM 3 // keypad three columns
char keys[ROW_NUM][COLUMN_NUM] = {
{'1', '2', '3'},
{'4', '5', '6'},
{'7', '8', '9'},
{'*', '0', '#'}
};
byte pin_rows[ROW_NUM] = {12, 14, 27, 26}; // ESP32 pin: GPIO12, GPIO14, GPIO27, GPIO26 connected to the row pins
byte pin_column[COLUMN_NUM] = {25, 33, 32}; // ESP32 pin: GPIO25, GPIO33, GPIO32 connected to the column pins
Keypad keypad = Keypad( makeKeymap(keys), pin_rows, pin_column, ROW_NUM, COLUMN_NUM );
const String password_1 = "1234"; // change your password here
const String password_2 = "4444"; // change your password here
const String password_3 = "55555"; // change your password here
String input_password;
void setup() {
Serial.begin(9600);
input_password.reserve(32); // maximum input characters is 32
pinMode(RELAY_PIN, OUTPUT);
digitalWrite(RELAY_PIN, HIGH); // lock the door
}
void loop() {
char key = keypad.getKey();
if (key) {
Serial.println(key);
if (key == '*') {
input_password = ""; // reset the input password
} else if (key == '#') {
if (input_password == password_1 || input_password == password_2 || input_password == password_3) {
Serial.println("Valid Password => unlock the door");
digitalWrite(RELAY_PIN, LOW); // unlock the door for 20 seconds
delay(20000);
digitalWrite(RELAY_PIN, HIGH); // lock the door
} else {
Serial.println("Invalid Password => Try again");
}
input_password = ""; // reset the input password
} else {
input_password += key; // append new character to input password string
}
}
}
Passos Rápidos
- Se esta é a primeira vez que você usa o ESP32, veja como configurar o ambiente para o ESP32 na Arduino IDE.
- Faça a ligação conforme a imagem acima.
- Conecte a placa ESP32 ao seu PC por meio de um cabo USB Type-C
- Abra a Arduino IDE no seu PC.
- Selecione a placa ESP32 correta (por exemplo, ESP32 Dev Module) e a porta COM.
- Clique no ícone Libraries na barra esquerda da Arduino IDE.
- Digite “keypad” na caixa de pesquisa e procure a biblioteca keypad de Mark Stanley, Alexander Brevig
- Clique no botão Install para instalar a biblioteca keypad.
- Copie o código acima e cole-o na Arduino IDE.
- Compile e faça upload do código para a placa ESP32 clicando no botão Upload na Arduino IDE
- Para simular a fechadura eletromagnética instalada na porta, coloque o eletroímã perto da placa de armadura.
- Pressione as teclas 1111 e pressione #
- Verifique a força de atração entre o eletroímã e a placa de armadura.
- Pressione as teclas 1234 e pressione #
- Verifique a força de atração entre o eletroímã e a placa de armadura.
- Veja o resultado no Serial Monitor
8
Serial.println("Hello World!");
Message (Enter to send message to 'ESP32 Dev Module' on 'COM15')
New Line
9600 baud
Invalid Password => Try again
Valid Password => unlock the door
Código ESP32 - Sistema de trava de porta com senha usando teclado, fechadura eletromagnética e LCD
O código abaixo adiciona um LCD I2C para exibir o status de acesso. Para a ligação com o LCD, você pode ver este tutorial ESP32 - Tutorial de LCD I2C
/*
* Este código de ESP32 foi desenvolvido por pt.newbiely.com
* Este código de ESP32 é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/esp32/esp32-door-lock-system-using-password
*/
#include <DIYables_LCD_I2C.h>
#include <Keypad.h>
#define RELAY_PIN 19 // ESP32 pin GPIO19 connected to the relay
#define ROW_NUM 4 // keypad four rows
#define COLUMN_NUM 3 // keypad three columns
char keys[ROW_NUM][COLUMN_NUM] = {
{'1', '2', '3'},
{'4', '5', '6'},
{'7', '8', '9'},
{'*', '0', '#'}
};
byte pin_rows[ROW_NUM] = {12, 14, 27, 26}; // ESP32 pin: GPIO12, GPIO14, GPIO27, GPIO26 connected to the row pins
byte pin_column[COLUMN_NUM] = {25, 33, 32}; // ESP32 pin: GPIO25, GPIO33, GPIO32 connected to the column pins
Keypad keypad = Keypad( makeKeymap(keys), pin_rows, pin_column, ROW_NUM, COLUMN_NUM );
const String password_1 = "1234"; // change your password here
const String password_2 = "4444"; // change your password here
const String password_3 = "55555"; // change your password here
String input_password;
DIYables_LCD_I2C lcd(0x27, 16, 2); // I2C address 0x27 (from DIYables LCD), 16 column and 2 rows
void setup() {
Serial.begin(9600);
input_password.reserve(32); // maximum input characters is 32
pinMode(RELAY_PIN, OUTPUT);
digitalWrite(RELAY_PIN, HIGH);
lcd.init(); // initialize the lcd
lcd.backlight();
}
void loop() {
char key = keypad.getKey();
if (key) {
Serial.println(key);
if (key == '*') {
input_password = ""; // reset the input password
lcd.clear();
} else if (key == '#') {
lcd.clear();
if (input_password == password_1 || input_password == password_2 || input_password == password_3) {
Serial.println("Valid Password => unlock the door");
lcd.setCursor(0, 0);
lcd.print("CORRECT!");
lcd.setCursor(0, 1);
lcd.print("DOOR UNLOCKED!");
digitalWrite(RELAY_PIN, LOW); // unlock the door for 20 seconds
delay(20000);
digitalWrite(RELAY_PIN, HIGH); // lock the door
} else {
Serial.println("Invalid Password => Try again");
lcd.setCursor(0, 0);
lcd.print("INCORRECT!");
lcd.setCursor(0, 1);
lcd.print("ACCESS DENIED!");
}
input_password = ""; // reset the input password
} else {
if (input_password.length() == 0) {
lcd.clear();
}
input_password += key; // append new character to input password string
lcd.setCursor(input_password.length(), 0); // move cursor to new position
lcd.print('*'); // print * key as hiden character
}
}
}
※ Nota:
O endereço do LCD I2C pode ser diferente de um fabricante para outro. No código, usamos o endereço 0x27, que é especificado pelo fabricante DIYables