Arduino - LCD Keypad Shield
O Arduino LCD Keypad Shield é um módulo útil que combina um display LCD 16x2 com seis botões de pressão (Right, Up, Down, Left, Select e Reset) para a interação com o usuário. Este tutorial vai guiar você na configuração e na programação deste shield usando uma placa Arduino.
Hardware Necessário
Or you can buy the following kits:
| 1 | × | DIYables STEM V3 Starter Kit (Arduino included) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgação: Alguns dos links desta seção são links de afiliado da Amazon. Podemos receber uma comissão pelas compras feitas por meio desses links, sem custo adicional para você. Agradecemos o seu apoio.
Sobre o LCD Keypad Shield
O LCD Keypad Shield tem:
- Um LCD 16x2 controlado pela biblioteca LiquidCrystal
- 5 botões de pressão conectados a um único pino analógico (A0)
- Um botão de reset para reiniciar o Arduino
- Um potenciômetro para ajustar o contraste do LCD
Pinagem
A tabela abaixo mostra o mapeamento de pinos entre o LCD Keypad Shield e o Arduino quando o shield é encaixado na placa.
| Pino do Shield | Função | Pino do Arduino |
|---|---|---|
| DB4 | Dados | 4 |
| DB5 | Dados | 5 |
| DB6 | Dados | 6 |
| DB7 | Dados | 7 |
| RS | Seleção de Registrador | 8 |
| E | Habilitação | 9 |
| Analog A0 | Entrada dos Botões | A0 |
Botão de Reset
O shield inclui um botão de reset, que está conectado ao pino de reset do Arduino. Pressionar este botão reinicia o Arduino, reiniciando o programa.
Potenciômetro
O shield tem um pequeno potenciômetro perto do display LCD. Ele serve para ajustar o contraste da tela LCD. Se o texto não estiver visível, tente girar o potenciômetro devagar para melhorar a visibilidade.
Diagrama de Ligação
Basta encaixar o LCD Keypad Shield na sua placa Arduino. Os pinos vão se alinhar automaticamente.
This image is created using Fritzing. Click to enlarge image
Código Arduino
/*
* Este código de Arduino foi desenvolvido por pt.newbiely.com
* Este código de Arduino é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/arduino/arduino-lcd-keypad-shield
*/
#include <LiquidCrystal.h>
LiquidCrystal lcd(8, 9, 4, 5, 6, 7);
void setup() {
Serial.begin(9600);
Serial.println("Started"); // Debugging
lcd.begin(16, 2);
lcd.print("Hello!");
delay(3000);
}
void loop() {
int key = analogRead(A0);
//Serial.println(key); // Debugging
lcd.clear();
if (key < 50)
lcd.print("RIGHT");
else if (key < 200)
lcd.print("UP");
else if (key < 400)
lcd.print("DOWN");
else if (key < 600)
lcd.print("LEFT");
else if (key < 800)
lcd.print("SELECT");
else if (key < 1000)
lcd.print("RST"); // If RST has a value, add here
else
lcd.print("Press key!");
delay(200);
}
Passos Rápidos
- Encaixe o LCD Keypad Shield no Arduino
- Conecte o Arduino ao PC via cabo USB
- Abra o Arduino IDE, selecione a placa e a porta corretas
- Copie o código acima e cole-o no Arduino IDE
- Clique no botão Upload no Arduino IDE para carregar o código no Arduino
- Pressione cada botão do shield, um por um, e verifique se o texto correspondente aparece no LCD.
- Confira o resultado no display LCD
Se o LCD continuar em branco, verifique se:
- O shield está conectado corretamente ao Arduino.
- O potenciômetro está ajustado para um contraste adequado.
- O código carregado corresponde ao exemplo fornecido.
- A placa Arduino está sendo alimentada corretamente.
Seguir estes passos deve ajudar você a fazer o seu Arduino LCD Keypad Shield funcionar corretamente!
Para mais funções de controle do display LCD, consulte este tutorial Arduino LiquidCrystal LCD.
Para melhorar a modularidade e a legibilidade, reorganizamos o código anterior em funções separadas:
/*
* Este código de Arduino foi desenvolvido por pt.newbiely.com
* Este código de Arduino é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/arduino/arduino-lcd-keypad-shield
*/
#include <LiquidCrystal.h>
// Define constants for key representations
const int KEY_RIGHT = 0;
const int KEY_UP = 1;
const int KEY_DOWN = 2;
const int KEY_LEFT = 3;
const int KEY_SELECT = 4;
const int KEY_NONE = 5;
LiquidCrystal lcd(8, 9, 4, 5, 6, 7);
int getKey() {
int analogValue = analogRead(A0);
//Serial.println(analogValue); // Debugging
if (analogValue < 50) return KEY_RIGHT;
else if (analogValue < 200) return KEY_UP;
else if (analogValue < 400) return KEY_DOWN;
else if (analogValue < 600) return KEY_LEFT;
else if (analogValue < 800) return KEY_SELECT;
else return KEY_NONE;
}
void setup() {
Serial.begin(9600);
Serial.println("Started"); // Debugging
lcd.begin(16, 2);
lcd.print("Hello!");
delay(3000);
}
void loop() {
lcd.clear();
int key = getKey();
switch (key) {
case KEY_RIGHT:
lcd.print("RIGHT");
break;
case KEY_UP:
lcd.print("UP");
break;
case KEY_DOWN:
lcd.print("DOWN");
break;
case KEY_LEFT:
lcd.print("LEFT");
break;
case KEY_SELECT:
lcd.print("SELECT");
break;
default:
lcd.print("Press key!");
break;
}
delay(200);
}
Vídeo
A demonstração em vídeo abaixo usa o código abaixo:
/*
* Este código de Arduino foi desenvolvido por pt.newbiely.com
* Este código de Arduino é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/arduino/arduino-lcd-keypad-shield
*/
#include <LiquidCrystal.h>
#include <Servo.h>
#include <DHT.h>
// ==================== PIN DEFINITIONS ====================
#define DHT_PIN 2
#define DHT_TYPE DHT11
#define SERVO_PIN 3
#define RED_LED_PIN 11
#define YELLOW_LED_PIN 12
#define GREEN_LED_PIN 13
// LCD Keypad Shield
LiquidCrystal lcd(8, 9, 4, 5, 6, 7);
DHT dht(DHT_PIN, DHT_TYPE);
Servo servo;
// ==================== BUTTONS ====================
enum Button {
BUTTON_NONE,
BUTTON_RIGHT,
BUTTON_UP,
BUTTON_DOWN,
BUTTON_LEFT,
BUTTON_SELECT
};
// ==================== STATES ====================
enum State {
MAIN_MENU,
SENSOR_MENU,
TEMPERATURE_VIEW,
HUMIDITY_VIEW,
SERVO_CONTROL,
LED_MENU,
RED_LED_CONTROL,
YELLOW_LED_CONTROL,
GREEN_LED_CONTROL,
AUTO_MODE
};
State currentState = MAIN_MENU;
// ==================== MENU DATA ====================
const char* mainMenu[] = {
"SENSOR",
"SERVO",
"LED",
"AUTO MODE"
};
const char* sensorMenu[] = {
"TEMPERATURE",
"HUMIDITY"
};
const char* ledMenu[] = {
"RED",
"YELLOW",
"GREEN"
};
int mainMenuIndex = 0;
int sensorMenuIndex = 0;
int ledMenuIndex = 0;
// ==================== DEVICE VARIABLES ====================
int servoAngle = 90;
bool redLEDState = false;
bool yellowLEDState = false;
bool greenLEDState = false;
float temperature = 0.0;
float humidity = 0.0;
unsigned long lastSensorRead = 0;
unsigned long lastAutoDisplay = 0;
const unsigned long sensorInterval = 2000;
const unsigned long autoDisplayInterval = 2000;
bool autoDisplayPage = false;
// ==================== READ BUTTON ====================
Button readButton() {
int value = analogRead(A0);
if (value < 50)
return BUTTON_RIGHT;
if (value < 200)
return BUTTON_UP;
if (value < 400)
return BUTTON_DOWN;
if (value < 600)
return BUTTON_LEFT;
if (value < 800)
return BUTTON_SELECT;
return BUTTON_NONE;
}
// ==================== WAIT FOR BUTTON RELEASE ====================
void waitButtonRelease() {
while (readButton() != BUTTON_NONE) {
delay(10);
}
delay(100);
}
// ==================== DISPLAY MAIN MENU ====================
void displayMainMenu() {
lcd.clear();
lcd.setCursor(0, 0);
lcd.print("MAIN MENU");
lcd.setCursor(0, 1);
lcd.print("> ");
lcd.print(mainMenu[mainMenuIndex]);
}
// ==================== DISPLAY SENSOR MENU ====================
void displaySensorMenu() {
lcd.clear();
lcd.setCursor(0, 0);
lcd.print("SENSOR");
lcd.setCursor(0, 1);
lcd.print("> ");
lcd.print(sensorMenu[sensorMenuIndex]);
}
// ==================== DISPLAY LED MENU ====================
void displayLEDMenu() {
lcd.clear();
lcd.setCursor(0, 0);
lcd.print("LED CONTROL");
lcd.setCursor(0, 1);
lcd.print("> ");
lcd.print(ledMenu[ledMenuIndex]);
}
// ==================== READ SENSOR ====================
void readSensor() {
float newTemperature = dht.readTemperature();
float newHumidity = dht.readHumidity();
if (!isnan(newTemperature)) {
temperature = newTemperature;
}
if (!isnan(newHumidity)) {
humidity = newHumidity;
}
}
// ==================== TEMPERATURE VIEW ====================
void showTemperature() {
readSensor();
lcd.setCursor(0, 0);
lcd.print("TEMPERATURE ");
lcd.setCursor(0, 1);
lcd.print(temperature, 1);
lcd.print((char)223);
lcd.print("C ");
}
// ==================== HUMIDITY VIEW ====================
void showHumidity() {
readSensor();
lcd.setCursor(0, 0);
lcd.print("HUMIDITY ");
lcd.setCursor(0, 1);
lcd.print(humidity, 1);
lcd.print("% ");
}
// ==================== SERVO DISPLAY ====================
void displayServoControl() {
lcd.clear();
lcd.setCursor(0, 0);
lcd.print("SERVO CONTROL");
lcd.setCursor(0, 1);
lcd.print("ANGLE: ");
lcd.print(servoAngle);
lcd.print((char)223);
}
// ==================== LED DISPLAY ====================
void displayLEDControl(const char* ledName, bool state) {
lcd.clear();
lcd.setCursor(0, 0);
lcd.print(ledName);
lcd.setCursor(0, 1);
if (state) {
lcd.print("STATUS: ON");
} else {
lcd.print("STATUS: OFF");
}
}
// ==================== AUTO MODE PAGE 1 ====================
void displayAutoPage1() {
lcd.clear();
lcd.setCursor(0, 0);
lcd.print("HUM:");
lcd.print(humidity, 0);
lcd.print("%");
lcd.setCursor(0, 1);
lcd.print("TEMP:");
lcd.print(temperature, 1);
lcd.print(" C");
}
// ==================== AUTO MODE PAGE 2 ====================
void displayAutoPage2() {
lcd.clear();
lcd.setCursor(0, 0);
lcd.print("LED: ");
if (temperature < 25.0) {
lcd.print("GREEN");
}
else if (temperature < 30.0) {
lcd.print("YELLOW");
}
else {
lcd.print("RED");
}
lcd.setCursor(0, 1);
lcd.print("SERVO: ");
lcd.print(servoAngle);
lcd.print(" DEG");
}
// ==================== AUTO MODE ====================
void runAutoMode() {
readSensor();
if (temperature < 31.3) {
digitalWrite(GREEN_LED_PIN, HIGH);
digitalWrite(YELLOW_LED_PIN, LOW);
digitalWrite(RED_LED_PIN, LOW);
servoAngle = 0;
servo.write(servoAngle);
}
else if (temperature < 31.5) {
digitalWrite(GREEN_LED_PIN, LOW);
digitalWrite(YELLOW_LED_PIN, HIGH);
digitalWrite(RED_LED_PIN, LOW);
servoAngle = 90;
servo.write(servoAngle);
}
else {
digitalWrite(GREEN_LED_PIN, LOW);
digitalWrite(YELLOW_LED_PIN, LOW);
digitalWrite(RED_LED_PIN, HIGH);
servoAngle = 180;
servo.write(servoAngle);
}
}
// ==================== MAIN MENU HANDLER ====================
void handleMainMenu(Button button) {
if (button == BUTTON_UP) {
mainMenuIndex--;
if (mainMenuIndex < 0) {
mainMenuIndex = 3;
}
displayMainMenu();
}
else if (button == BUTTON_DOWN) {
mainMenuIndex++;
if (mainMenuIndex > 3) {
mainMenuIndex = 0;
}
displayMainMenu();
}
else if (button == BUTTON_SELECT) {
switch (mainMenuIndex) {
case 0:
currentState = SENSOR_MENU;
sensorMenuIndex = 0;
displaySensorMenu();
break;
case 1:
currentState = SERVO_CONTROL;
displayServoControl();
break;
case 2:
currentState = LED_MENU;
ledMenuIndex = 0;
displayLEDMenu();
break;
case 3:
currentState = AUTO_MODE;
autoDisplayPage = false;
lastSensorRead = millis();
lastAutoDisplay = millis();
runAutoMode();
displayAutoPage1();
break;
}
}
}
// ==================== SENSOR MENU HANDLER ====================
void handleSensorMenu(Button button) {
if (button == BUTTON_UP) {
sensorMenuIndex--;
if (sensorMenuIndex < 0) {
sensorMenuIndex = 1;
}
displaySensorMenu();
}
else if (button == BUTTON_DOWN) {
sensorMenuIndex++;
if (sensorMenuIndex > 1) {
sensorMenuIndex = 0;
}
displaySensorMenu();
}
else if (button == BUTTON_SELECT) {
if (sensorMenuIndex == 0) {
lcd.clear();
currentState = TEMPERATURE_VIEW;
lastSensorRead = millis();
showTemperature();
}
else {
lcd.clear();
currentState = HUMIDITY_VIEW;
lastSensorRead = millis();
showHumidity();
}
}
else if (button == BUTTON_LEFT) {
currentState = MAIN_MENU;
displayMainMenu();
}
}
// ==================== TEMPERATURE HANDLER ====================
void handleTemperatureView(Button button) {
if (button == BUTTON_LEFT || button == BUTTON_SELECT) {
currentState = SENSOR_MENU;
displaySensorMenu();
}
}
// ==================== HUMIDITY HANDLER ====================
void handleHumidityView(Button button) {
if (button == BUTTON_LEFT || button == BUTTON_SELECT) {
currentState = SENSOR_MENU;
displaySensorMenu();
}
}
// ==================== SERVO HANDLER ====================
void handleServoControl(Button button) {
if (button == BUTTON_UP) {
servoAngle++;
if (servoAngle > 180) {
servoAngle = 180;
}
servo.write(servoAngle);
displayServoControl();
}
else if (button == BUTTON_DOWN) {
servoAngle--;
if (servoAngle < 0) {
servoAngle = 0;
}
servo.write(servoAngle);
displayServoControl();
}
else if (button == BUTTON_RIGHT) {
servoAngle += 10;
if (servoAngle > 180) {
servoAngle = 180;
}
servo.write(servoAngle);
displayServoControl();
}
else if (button == BUTTON_LEFT) {
servoAngle -= 10;
if (servoAngle < 0) {
servoAngle = 0;
}
servo.write(servoAngle);
displayServoControl();
}
else if (button == BUTTON_SELECT) {
currentState = MAIN_MENU;
displayMainMenu();
}
}
// ==================== LED MENU HANDLER ====================
void handleLEDMenu(Button button) {
if (button == BUTTON_UP) {
ledMenuIndex--;
if (ledMenuIndex < 0) {
ledMenuIndex = 2;
}
displayLEDMenu();
}
else if (button == BUTTON_DOWN) {
ledMenuIndex++;
if (ledMenuIndex > 2) {
ledMenuIndex = 0;
}
displayLEDMenu();
}
else if (button == BUTTON_SELECT) {
switch (ledMenuIndex) {
case 0:
currentState = RED_LED_CONTROL;
displayLEDControl("RED LED", redLEDState);
break;
case 1:
currentState = YELLOW_LED_CONTROL;
displayLEDControl("YELLOW LED", yellowLEDState);
break;
case 2:
currentState = GREEN_LED_CONTROL;
displayLEDControl("GREEN LED", greenLEDState);
break;
}
}
else if (button == BUTTON_LEFT) {
currentState = MAIN_MENU;
displayMainMenu();
}
}
// ==================== RED LED HANDLER ====================
void handleRedLED(Button button) {
if (button == BUTTON_RIGHT) {
redLEDState = !redLEDState;
digitalWrite(RED_LED_PIN, redLEDState ? HIGH : LOW);
displayLEDControl("RED LED", redLEDState);
}
else if (button == BUTTON_LEFT) {
currentState = LED_MENU;
displayLEDMenu();
}
}
// ==================== YELLOW LED HANDLER ====================
void handleYellowLED(Button button) {
if (button == BUTTON_RIGHT) {
yellowLEDState = !yellowLEDState;
digitalWrite(YELLOW_LED_PIN, yellowLEDState ? HIGH : LOW);
displayLEDControl("YELLOW LED", yellowLEDState);
}
else if (button == BUTTON_LEFT) {
currentState = LED_MENU;
displayLEDMenu();
}
}
// ==================== GREEN LED HANDLER ====================
void handleGreenLED(Button button) {
if (button == BUTTON_RIGHT) {
greenLEDState = !greenLEDState;
digitalWrite(GREEN_LED_PIN, greenLEDState ? HIGH : LOW);
displayLEDControl("GREEN LED", greenLEDState);
}
else if (button == BUTTON_LEFT) {
currentState = LED_MENU;
displayLEDMenu();
}
}
// ==================== AUTO MODE HANDLER ====================
void handleAutoMode(Button button) {
if (button == BUTTON_LEFT || button == BUTTON_SELECT) {
digitalWrite(RED_LED_PIN, LOW);
digitalWrite(YELLOW_LED_PIN, LOW);
digitalWrite(GREEN_LED_PIN, LOW);
redLEDState = false;
yellowLEDState = false;
greenLEDState = false;
servoAngle = 90;
servo.write(servoAngle);
currentState = MAIN_MENU;
displayMainMenu();
}
}
// ==================== SETUP ====================
void setup() {
lcd.begin(16, 2);
dht.begin();
servo.attach(SERVO_PIN);
servo.write(servoAngle);
pinMode(RED_LED_PIN, OUTPUT);
pinMode(YELLOW_LED_PIN, OUTPUT);
pinMode(GREEN_LED_PIN, OUTPUT);
digitalWrite(RED_LED_PIN, LOW);
digitalWrite(YELLOW_LED_PIN, LOW);
digitalWrite(GREEN_LED_PIN, LOW);
lcd.clear();
lcd.setCursor(0, 0);
lcd.print("SMART CONTROL");
lcd.setCursor(0, 1);
lcd.print("STATION");
delay(2000);
displayMainMenu();
}
// ==================== LOOP ====================
void loop() {
Button button = readButton();
if (button != BUTTON_NONE) {
switch (currentState) {
case MAIN_MENU: handleMainMenu(button); break;
case SENSOR_MENU: handleSensorMenu(button); break;
case TEMPERATURE_VIEW: handleTemperatureView(button); break;
case HUMIDITY_VIEW: handleHumidityView(button); break;
case SERVO_CONTROL: handleServoControl(button); break;
case LED_MENU: handleLEDMenu(button); break;
case RED_LED_CONTROL: handleRedLED(button); break;
case YELLOW_LED_CONTROL: handleYellowLED(button); break;
case GREEN_LED_CONTROL: handleGreenLED(button); break;
case AUTO_MODE: handleAutoMode(button); break;
}
waitButtonRelease();
}
// ===== AUTOMATIC DATA UPDATE =====
if (currentState == AUTO_MODE) {
if (millis() - lastSensorRead >= sensorInterval) {
lastSensorRead = millis();
runAutoMode();
}
if (millis() - lastAutoDisplay >= autoDisplayInterval) {
lastAutoDisplay = millis();
autoDisplayPage = !autoDisplayPage;
if (autoDisplayPage) {
displayAutoPage2();
} else {
displayAutoPage1();
}
}
}
if (currentState == TEMPERATURE_VIEW || currentState == HUMIDITY_VIEW) {
if (millis() - lastSensorRead >= sensorInterval) {
lastSensorRead = millis();
if (currentState == TEMPERATURE_VIEW) {
showTemperature();
} else if (currentState == HUMIDITY_VIEW) {
showHumidity();
}
}
}
}