Arduino - Motor DC - Chave de Fim de Curso
Neste tutorial de Arduino, vamos aprender a usar o Arduino para controlar um motor DC com uma chave de fim de curso e o driver L298N. Em detalhes, vamos aprender:
- Como parar o motor DC quando uma chave de fim de curso é tocada
- Como mudar a direção do motor DC quando uma chave de fim de curso é tocada
- Como mudar a direção do motor DC quando duas chaves de fim de curso são tocadas
Hardware Necessário
Or you can buy the following kits:
| 1 | × | DIYables STEM V3 Starter Kit (Arduino included) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgação: Alguns dos links desta seção são links de afiliado da Amazon. Podemos receber uma comissão pelas compras feitas por meio desses links, sem custo adicional para você. Agradecemos o seu apoio.
Sobre o Motor DC e a Chave de Fim de Curso
Se você não conhece o motor DC e a chave de fim de curso (pinagem, como funciona, como programar...), aprenda sobre eles nos seguintes tutoriais:
- Tutorial Arduino - Chave de Fim de Curso
- Tutorial Arduino - Controlar Motor DC
Diagrama de Ligação
Este tutorial fornece os códigos Arduino para dois casos: um motor DC + uma chave de fim de curso, e um motor DC + duas chaves de fim de curso.
- Diagrama de ligação entre o motor DC e uma chave de fim de curso
This image is created using Fritzing. Click to enlarge image
- Diagrama de ligação entre o motor DC e duas chaves de fim de curso
This image is created using Fritzing. Click to enlarge image
Código Arduino - Parar o Motor DC com uma Chave de Fim de Curso
O código abaixo faz o motor DC girar sem parar e parar imediatamente quando uma chave de fim de curso é tocada
/*
* Este código de Arduino foi desenvolvido por pt.newbiely.com
* Este código de Arduino é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/arduino/arduino-dc-motor-limit-switch
*/
#include <ezButton.h>
#define ENA_PIN 7 // The Arduino pin connected to the EN1 pin L298N
#define IN1_PIN 6 // The Arduino pin connected to the IN1 pin L298N
#define IN2_PIN 5 // The Arduino pin connected to the IN2 pin L298N
ezButton limitSwitch(A1); // create ezButton object that attach to pin A1
void setup() {
Serial.begin(9600);
limitSwitch.setDebounceTime(50); // set debounce time to 50 milliseconds
// initialize digital pins as outputs.
pinMode(ENA_PIN, OUTPUT);
pinMode(IN1_PIN, OUTPUT);
pinMode(IN2_PIN, OUTPUT);
digitalWrite(ENA_PIN, HIGH); // max speed
digitalWrite(IN1_PIN, HIGH); // control motor A spins clockwise
digitalWrite(IN2_PIN, LOW); // control motor A spins clockwise
}
void loop() {
limitSwitch.loop(); // MUST call the loop() function first
if (limitSwitch.isPressed()) {
Serial.println(F("The limit switch: TOUCHED"));
digitalWrite(IN1_PIN, LOW); // stop motor
digitalWrite(IN2_PIN, LOW); // stop motor
}
}
Passos Rápidos
- Conecte o Arduino ao PC usando o cabo USB
- Abra a Arduino IDE, selecione a placa e a porta corretas
- Vá até o ícone Libraries na barra esquerda da Arduino IDE.
- Pesquise “ezButton” e encontre a biblioteca de botão da ArduinoGetStarted.com
- Clique no botão Install para instalar a biblioteca ezButton.
- Copie o código acima e abra-o na Arduino IDE
- Clique no botão Upload na Arduino IDE para carregar o código no Arduino
- Se a ligação estiver correta, você verá o motor girar no sentido horário.
- Toque na chave de fim de curso
- Você verá o motor parar imediatamente
- O resultado no Serial Monitor fica assim
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno' on 'COM15')
New Line
9600 baud
The limit switch: TOUCHED
The DC motor is STOPPED
The DC motor is STOPPED
The DC motor is STOPPED
The DC motor is STOPPED
Explicação do Código
Leia a explicação linha por linha nos comentários do código!
Código Arduino - Mudar a Direção do Motor DC com uma Chave de Fim de Curso
O código abaixo faz o motor DC girar sem parar e mudar de direção quando uma chave de fim de curso é tocada
/*
* Este código de Arduino foi desenvolvido por pt.newbiely.com
* Este código de Arduino é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/arduino/arduino-dc-motor-limit-switch
*/
#include <ezButton.h>
#define DIRECTION_CCW -1
#define DIRECTION_CW 1
// constants won't change
#define ENA_PIN 7 // The Arduino pin connected to the EN1 pin L298N
#define IN1_PIN 6 // The Arduino pin connected to the IN1 pin L298N
#define IN2_PIN 5 // The Arduino pin connected to the IN2 pin L298N
ezButton limitSwitch(A1); // create ezButton object that attach to pin A1
int direction = DIRECTION_CW;
void setup() {
Serial.begin(9600);
limitSwitch.setDebounceTime(50); // set debounce time to 50 milliseconds
// initialize digital pins as outputs.
pinMode(ENA_PIN, OUTPUT);
pinMode(IN1_PIN, OUTPUT);
pinMode(IN2_PIN, OUTPUT);
digitalWrite(ENA_PIN, HIGH); // max speed
digitalWrite(IN1_PIN, HIGH); // control motor A spins clockwise
digitalWrite(IN2_PIN, LOW); // control motor A spins clockwise
}
void loop() {
limitSwitch.loop(); // MUST call the loop() function first
if (limitSwitch.isPressed()) {
Serial.println(F("The limit switch: TOUCHED"));
direction *= -1; // change direction
Serial.print(F("The direction -> "));
if (direction == DIRECTION_CW) {
Serial.println(F("CLOCKWISE"));
digitalWrite(IN1_PIN, HIGH); // control motor A spins clockwise
digitalWrite(IN2_PIN, LOW); // control motor A spins clockwise
} else {
Serial.println(F("ANTI-CLOCKWISE"));
digitalWrite(IN1_PIN, LOW); // control motor A spins anti-clockwise
digitalWrite(IN2_PIN, HIGH); // control motor A spins anti-clockwise
}
}
}
Passos Rápidos
- Copie o código acima e abra-o na Arduino IDE
- Clique no botão Upload na Arduino IDE para carregar o código no Arduino
- Se a ligação estiver correta, você verá o motor girar no sentido horário.
- Toque na chave de fim de curso
- Você verá a direção do motor DC mudar para o sentido anti-horário
- Toque na chave de fim de curso novamente
- Você verá a direção do motor DC mudar para o sentido horário
- O resultado no Serial Monitor fica assim
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno' on 'COM15')
New Line
9600 baud
The limit switch: TOUCHED
The direction -> ANTI-CLOCKWISE
The limit switch: TOUCHED
The direction -> CLOCKWISE
Código Arduino - Mudar a Direção do Motor DC com duas Chaves de Fim de Curso
O código abaixo faz o motor DC girar sem parar e mudar de direção quando uma das duas chaves de fim de curso é tocada
/*
* Este código de Arduino foi desenvolvido por pt.newbiely.com
* Este código de Arduino é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/arduino/arduino-dc-motor-limit-switch
*/
#include <ezButton.h>
#define DIRECTION_CCW -1
#define DIRECTION_CW 1
#define ENA_PIN 7 // The Arduino pin connected to the EN1 pin L298N
#define IN1_PIN 6 // The Arduino pin connected to the IN1 pin L298N
#define IN2_PIN 5 // The Arduino pin connected to the IN2 pin L298N
ezButton limitSwitch_1(A0); // create ezButton object that attach to pin A0
ezButton limitSwitch_2(A1); // create ezButton object that attach to pin A1
int direction = DIRECTION_CW;
int prev_direction = DIRECTION_CW;
void setup() {
Serial.begin(9600);
limitSwitch_1.setDebounceTime(50); // set debounce time to 50 milliseconds
limitSwitch_2.setDebounceTime(50); // set debounce time to 50 milliseconds
// initialize digital pins as outputs.
pinMode(ENA_PIN, OUTPUT);
pinMode(IN1_PIN, OUTPUT);
pinMode(IN2_PIN, OUTPUT);
digitalWrite(ENA_PIN, HIGH); // max speed
digitalWrite(IN1_PIN, HIGH); // control motor A spins clockwise
digitalWrite(IN2_PIN, LOW); // control motor A spins clockwise
}
void loop() {
limitSwitch_1.loop(); // MUST call the loop() function first
limitSwitch_2.loop(); // MUST call the loop() function first
if (limitSwitch_1.isPressed()) {
direction *= -1; // change direction
Serial.println(F("The limit switch 1: TOUCHED"));
}
if (limitSwitch_2.isPressed()) {
direction *= -1; // change direction
Serial.println(F("The limit switch 2: TOUCHED"));
}
if (prev_direction != direction) {
Serial.print(F("The direction -> "));
if (direction == DIRECTION_CW) {
Serial.println(F("CLOCKWISE"));
digitalWrite(IN1_PIN, HIGH); // control motor A spins clockwise
digitalWrite(IN2_PIN, LOW); // control motor A spins clockwise
} else {
Serial.println(F("ANTI-CLOCKWISE"));
digitalWrite(IN1_PIN, LOW); // control motor A spins anti-clockwise
digitalWrite(IN2_PIN, HIGH); // control motor A spins anti-clockwise
}
prev_direction = direction;
}
}
Passos Rápidos
- Copie o código acima e abra-o na Arduino IDE
- Clique no botão Upload na Arduino IDE para carregar o código no Arduino
- Se a ligação estiver correta, você verá o motor girar no sentido horário.
- Toque na chave de fim de curso 1
- Você verá a direção do motor DC mudar para o sentido anti-horário
- Toque na chave de fim de curso 2
- Você verá a direção do motor DC mudar para o sentido horário
- O resultado no Serial Monitor fica assim
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno' on 'COM15')
New Line
9600 baud
The limit switch 1: TOUCHED
The direction -> ANTI-CLOCKWISE
The limit switch 2: TOUCHED
The direction -> CLOCKWISE