Arduino - Notificação por E-mail de Porta Aberta
Neste guia, vamos aprender a usar um Arduino para enviar e-mails quando uma porta é aberta. Vamos explicar como configurar tudo, de quais peças você precisa, e dar passos detalhados para conectar um Arduino a um sensor de porta e a um serviço de e-mail. Isso vai ajudar a manter sua casa segura, enviando a você alertas instantâneos por e-mail quando a porta for aberta.
Hardware Necessário
Or you can buy the following kits:
| 1 | × | DIYables STEM V4 IoT Starter Kit (Arduino included) | |
| 1 | × | DIYables STEM V4B IoT Starter Kit (Arduino included) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgação: Alguns dos links desta seção são links de afiliado da Amazon. Podemos receber uma comissão pelas compras feitas por meio desses links, sem custo adicional para você. Agradecemos o seu apoio.
Sobre o Sensor de Porta e o Gmail
Oferecemos tutoriais detalhados sobre Sensores de Porta e Gmail. Cada guia inclui informações completas e instruções claras, passo a passo, sobre a configuração do hardware, o princípio de funcionamento e como conectar e programar o Arduino. Você pode saber mais sobre esses tutoriais pelos links abaixo:
- Tutorial Arduino - Sensor de Porta
- Tutorial Arduino - Gmail
Diagrama de Ligação entre o Sensor de Porta e o Arduino
This image is created using Fritzing. Click to enlarge image
Código Arduino
/*
* Este código de Arduino foi desenvolvido por pt.newbiely.com
* Este código de Arduino é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/arduino/arduino-door-open-email-notification
*/
#include <WiFiS3.h>
#include <ESP_Mail_Client.h>
#define WIFI_SSID "YOUR_WIFI_SSID" // CHANGE IT
#define WIFI_PASSWORD "YOUR_WIFI_PASSWORD" // CHANGE IT
// the sender email credentials
#define SENDER_EMAIL "xxxxxx@gmail.com" // CHANGE IT
#define SENDER_PASSWORD "xxxx xxxx xxxx xxxx" // CHANGE IT to your Google App password
#define RECIPIENT_EMAIL "xxxxxx@gmail.com" // CHANGE IT
#define SMTP_HOST "smtp.gmail.com"
#define SMTP_PORT 587
#define DOOR_SENSOR_PIN 13 // Arduino pin connected to door sensor's pin
int door_state; // current state of door sensor
int prev_door_state; // previous state of door sensor
SMTPSession smtp;
void setup() {
Serial.begin(9600);
WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
Serial.print("Connecting to Wi-Fi");
while (WiFi.status() != WL_CONNECTED) {
Serial.print(".");
delay(300);
}
Serial.println();
Serial.print("Connected with IP: ");
Serial.println(WiFi.localIP());
Serial.println();
pinMode(DOOR_SENSOR_PIN, INPUT_PULLUP); // set Arduino pin to input pull-up mode
door_state = digitalRead(DOOR_SENSOR_PIN); // read state
}
void loop() {
prev_door_state = door_state; // save the last state
door_state = digitalRead(DOOR_SENSOR_PIN); // read new state
if (prev_door_state == LOW && door_state == HIGH) { // state change: LOW -> HIGH
Serial.println("The door is opened");
String subject = "Email Notification from Arduino";
String textMsg = "This is an email sent from Arduino.\n";
textMsg += "Your door is opened";
gmail_send(subject, textMsg);
} else if (prev_door_state == HIGH && door_state == LOW) { // state change: HIGH -> LOW
Serial.println("The door is closed");
}
}
void gmail_send(String subject, String textMsg) {
// set the network reconnection option
MailClient.networkReconnect(true);
smtp.debug(1);
smtp.callback(smtpCallback);
Session_Config config;
// set the session config
config.server.host_name = SMTP_HOST;
config.server.port = SMTP_PORT;
config.login.email = SENDER_EMAIL;
config.login.password = SENDER_PASSWORD;
config.login.user_domain = F("127.0.0.1");
config.time.ntp_server = F("pool.ntp.org,time.nist.gov");
config.time.gmt_offset = 3;
config.time.day_light_offset = 0;
// declare the message class
SMTP_Message message;
// set the message headers
message.sender.name = F("Arduino");
message.sender.email = SENDER_EMAIL;
message.subject = subject;
message.addRecipient(F("To Whom It May Concern"), RECIPIENT_EMAIL);
message.text.content = textMsg;
message.text.transfer_encoding = "base64";
message.text.charSet = F("utf-8");
message.priority = esp_mail_smtp_priority::esp_mail_smtp_priority_low;
// set the custom message header
message.addHeader(F("Message-ID: <abcde.fghij@gmail.com>"));
// connect to the server
if (!smtp.connect(&config)) {
Serial.println("Connection error: ");
Serial.print("- Status Code: ");
Serial.println(smtp.statusCode());
Serial.print("- Error Code: ");
Serial.println(smtp.errorCode());
Serial.print("- Reason: ");
Serial.println(smtp.errorReason().c_str());
return;
}
if (!smtp.isLoggedIn()) {
Serial.println("Not yet logged in.");
} else {
if (smtp.isAuthenticated())
Serial.println("Successfully logged in.");
else
Serial.println("Connected with no Auth.");
}
// start sending Email and close the session
if (!MailClient.sendMail(&smtp, &message)) {
Serial.println("Connection error: ");
Serial.print("- Status Code: ");
Serial.println(smtp.statusCode());
Serial.print("- Error Code: ");
Serial.println(smtp.errorCode());
Serial.print("- Reason: ");
Serial.println(smtp.errorReason().c_str());
}
}
// callback function to get the Email sending status
void smtpCallback(SMTP_Status status) {
// print the current status
Serial.println(status.info());
// print the sending result
if (status.success()) {
for (size_t i = 0; i < smtp.sendingResult.size(); i++) {
// get the result item
SMTP_Result result = smtp.sendingResult.getItem(i);
Serial.print("Status: ");
if (result.completed)
Serial.println("success");
else
Serial.println("failed");
Serial.print("Recipient: ");
Serial.println(result.recipients.c_str());
Serial.print("Subject: ");
Serial.println(result.subject.c_str());
}
Serial.println("----------------\n");
// free the memory
smtp.sendingResult.clear();
}
}
Passos Rápidos
- Se esta é a primeira vez que você usa o Arduino Uno R4, veja como configurar o ambiente para o Arduino Uno R4 na Arduino IDE.
- Fixe o sensor de porta na sua porta.
- Ligue a placa Arduino ao sensor de porta.
- Conecte a placa Arduino ao seu computador usando um cabo USB Type-C.
- Abra a Arduino IDE no seu computador.
- Selecione a placa Arduino correta (Arduino Uno R4 WiFi) e a porta COM.
- Na Arduino IDE, clique no ícone "Library Manager" no menu à esquerda para abri-lo.
- Digite ESP Mail Client na caixa de pesquisa e procure o ESP Mail Client da Mobizt.
- Pressione o botão Install para adicionar a biblioteca ESP Mail Client.
- Copie o código fornecido e abra-o na Arduino IDE.
- Atualize os dados do seu WiFi (nome da rede e senha) no código. Altere os valores de WIFI_SSID e WIFI_PASSWORD para os seus.
- Edite o e-mail e a senha do remetente no código. Modifique SENDER_EMAIL e SENDER_PASSWORD.
※ Nota:
Certifique-se de que o e-mail do remetente é do Gmail. Use a Senha de app do passo anterior como senha do remetente. O e-mail do destinatário pode ser de qualquer tipo.
- Pressione o botão Upload na Arduino IDE para carregar o código no Arduino
- Abra o Serial Monitor
- Abra a porta
- Veja os resultados no Serial Monitor.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno' on 'COM15')
New Line
9600 baud
The door is opened
#### Email sent successfully
> C: Email sent successfully
----------------
Message sent success: 1
Message sent failed: 0
----------------
Message No: 1
Status: success
Date/Time: May 27, 2024 04:42:50
Recipient: xxxxxx@gmail.com
Subject: Email Notification from Arduino
----------------
- Verifique a caixa de entrada do e-mail do destinatário. Você receberá um e-mail parecido com o seguinte:
