Arduino - Ethernet
Este guia ensina como conectar o Arduino à internet ou à sua rede local usando o módulo Ethernet W5500. Vamos abordar os seguintes detalhes:
- Conectar o Arduino ao Módulo Ethernet W5500
- Programar o Arduino para Requisições HTTP via Ethernet
- Configurar um Servidor Web Simples no Arduino Usando Ethernet
Hardware Necessário
Or you can buy the following kits:
| 1 | × | DIYables STEM V3 Starter Kit (Arduino included) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgação: Alguns dos links desta seção são links de afiliado da Amazon. Podemos receber uma comissão pelas compras feitas por meio desses links, sem custo adicional para você. Agradecemos o seu apoio.
Sobre o módulo Ethernet W5500
O módulo Ethernet W5500 possui dois tipos de conexão:
- Interface RJ45: Use-a para conectar a um roteador ou switch com um cabo Ethernet.
- Interface SPI: Use-a para conectar a uma placa Arduino. Ela tem 10 pinos:
- Pino NC: Não conecte este pino.
- Pino INT: Não conecte este pino.
- Pino RST: Este é o pino de reset, conecte-o ao pino RESET do Arduino.
- Pino GND: Conecte este pino ao pino GND do Arduino.
- Pino 5V: Não conecte este pino.
- Pino 3.3V: Conecte este pino ao pino 3.3V do Arduino.
- Pino MISO: Conecte este pino ao pino SPI MISO do Arduino.
- Pino MOSI: Conecte este pino ao pino SPI MOSI do Arduino.
- Pino SCS: Conecte este pino ao pino SPI CS do Arduino.
- Pino SCLK: Conecte este pino ao pino SPI SCK do Arduino.
image source: diyables.io
Diagrama de Ligação entre o Arduino e o módulo Ethernet W5500
This image is created using Fritzing. Click to enlarge image
image source: diyables.io
Código Arduino para Módulo Ethernet - Fazendo requisição HTTP via Ethernet
Este código atua como um cliente web, enviando requisições HTTP para o servidor web localizado em http://example.com/.
/*
* Este código de Arduino foi desenvolvido por pt.newbiely.com
* Este código de Arduino é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/arduino/arduino-ethernet
*/
#include <SPI.h>
#include <Ethernet.h>
// replace the MAC address below by the MAC address printed on a sticker on the Arduino Shield 2
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
EthernetClient client;
int HTTP_PORT = 80;
String HTTP_METHOD = "GET"; // or POST
char HOST_NAME[] = "example.com";
String PATH_NAME = "/";
void setup() {
Serial.begin(9600);
delay(1000);
Serial.println("Arduino - Ethernet Tutorial");
// initialize the Ethernet shield using DHCP:
if (Ethernet.begin(mac) == 0) {
Serial.println("Failed to obtaining an IP address");
// check for Ethernet hardware present
if (Ethernet.hardwareStatus() == EthernetNoHardware)
Serial.println("Ethernet shield was not found");
// check for Ethernet cable
if (Ethernet.linkStatus() == LinkOFF)
Serial.println("Ethernet cable is not connected.");
while (true)
;
}
// connect to web server on port 80:
if (client.connect(HOST_NAME, HTTP_PORT)) {
// if connected:
Serial.println("Connected to server");
// make a HTTP request:
// send HTTP header
client.println(HTTP_METHOD + " " + PATH_NAME + " HTTP/1.1");
client.println("Host: " + String(HOST_NAME));
client.println("Connection: close");
client.println(); // end HTTP header
while (client.connected()) {
if (client.available()) {
// read an incoming byte from the server and print it to serial monitor:
char c = client.read();
Serial.print(c);
}
}
// the server's disconnected, stop the client:
client.stop();
Serial.println();
Serial.println("disconnected");
} else { // if not connected:
Serial.println("connection failed");
}
}
void loop() {
}
Passos Rápidos
- Se você é novo no Arduino, comece configurando o ambiente na Arduino IDE seguindo o guia aqui.
- Conecte o módulo Ethernet ao Arduino de acordo com o diagrama de ligação fornecido.
- Ligue o Arduino ao seu computador usando um cabo USB.
- Conecte o módulo Ethernet ao seu roteador ou switch usando um cabo Ethernet.
- Abra a Arduino IDE no seu computador.
- Escolha a placa Arduino correta, como o Arduino Uno, e selecione a porta COM.
- Clique no ícone Libraries na barra esquerda da Arduino IDE.
- Pesquise “Ethernet” e encontre a biblioteca Ethernet da Various
- Clique no botão Install para instalar a biblioteca Ethernet.
- Abra o Serial Monitor na Arduino IDE.
- Copie o código fornecido e cole-o na Arduino IDE.
- Clique no botão Upload na Arduino IDE para carregar o código no Arduino.
- Para ver a saída, confira o Serial Monitor, que deve exibir o resultado como mostrado.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno' on 'COM15')
New Line
9600 baud
Arduino - Ethernet Tutorial
Connected to server
HTTP/1.1 200 OK
Accept-Ranges: bytes
Age: 208425
Cache-Control: max-age=604800
Content-Type: text/html; charset=UTF-8
Date: Fri, 12 Jul 2024 07:08:42 GMT
Etag: "3147526947"
Expires: Fri, 19 Jul 2024 07:08:42 GMT
Last-Modified: Thu, 17 Oct 2019 07:18:26 GMT
Server: ECAcc (lac/55B8)
Vary: Accept-Encoding
X-Cache: HIT
Content-Length: 1256
Connection: close
<!doctype html>
<html>
<head>
<title>Example Domain</title>
<meta charset="utf-8" />
<meta http-equiv="Content-type" content="text/html; charset=utf-8" />
<meta name="viewport" content="width=device-width, initial-scale=1" />
</head>
<body>
<div>
<h1>Example Domain</h1>
<p>This domain is for use in illustrative examples in documents. You may use this
domain in literature without prior coordination or asking for permission.</p>
<p><a href="https://www.iana.org/domains/example">More information...</a></p>
</div>
</body>
</html>
disconnected
※ Nota:
Se outro dispositivo na mesma rede tiver o mesmo endereço MAC, pode não funcionar.
Código Arduino para Módulo Ethernet - Servidor Web
O código abaixo transforma o Arduino em um servidor web. Este servidor envia uma página web simples para os navegadores web.
/*
* Este código de Arduino foi desenvolvido por pt.newbiely.com
* Este código de Arduino é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/arduino/arduino-ethernet
*/
#include <SPI.h>
#include <Ethernet.h>
// replace the MAC address below by the MAC address printed on a sticker on the Arduino Shield 2
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
EthernetServer server(80);
void setup() {
Serial.begin(9600);
delay(1000);
Serial.println("Arduino - Ethernet Tutorial");
// initialize the Ethernet shield using DHCP:
if (Ethernet.begin(mac) == 0) {
Serial.println("Failed to obtaining an IP address");
// check for Ethernet hardware present
if (Ethernet.hardwareStatus() == EthernetNoHardware)
Serial.println("Ethernet shield was not found");
// check for Ethernet cable
if (Ethernet.linkStatus() == LinkOFF)
Serial.println("Ethernet cable is not connected.");
while (true)
;
}
server.begin();
Serial.print("Arduino - Web Server IP Address: ");
Serial.println(Ethernet.localIP());
}
void loop() {
// listen for incoming clients
EthernetClient client = server.available();
if (client) {
Serial.println("new client");
// an HTTP request ends with a blank line
bool currentLineIsBlank = true;
while (client.connected()) {
if (client.available()) {
char c = client.read();
Serial.write(c);
// if you've gotten to the end of the line (received a newline
// character) and the line is blank, the HTTP request has ended,
// so you can send a reply
if (c == '\n' && currentLineIsBlank) {
// send a standard HTTP response header
client.println("HTTP/1.1 200 OK");
client.println("Content-Type: text/html");
client.println("Connection: close"); // the connection will be closed after completion of the response
client.println();
client.println("<!DOCTYPE HTML>");
client.println("<html>");
client.println("<body>");
client.println("<h1>Arduino - Web Server with Ethernet</h1>");
client.println("</body>");
client.println("</html>");
break;
}
if (c == '\n') {
// you're starting a new line
currentLineIsBlank = true;
} else if (c != '\r') {
// you've gotten a character on the current line
currentLineIsBlank = false;
}
}
}
// give the web browser time to receive the data
delay(1);
// close the connection:
client.stop();
Serial.println("client disconnected");
}
}
Passos Rápidos
- Copie o código acima e cole-o na Arduino IDE
- Clique no botão Upload na Arduino IDE para carregar o código no Arduino
- Veja o resultado no Serial Monitor, ele aparece assim:
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno' on 'COM15')
New Line
9600 baud
Arduino - Ethernet Tutorial
Arduino - Web Server IP Address: 192.168.0.2
- Copie o endereço IP acima e cole-o na barra de endereços do seu navegador web. Você verá uma página web simples que o Arduino está exibindo.
