ESP8266 - GPS
Este tutorial ensina como usar o ESP8266 com um módulo GPS NEO-6M. Em detalhes, vamos aprender:
- Como conectar o ESP8266 a um módulo GPS NEO-6M
- Como programar o ESP8266 para ler as coordenadas GPS (longitude, latitude e altitude) de um módulo GPS NEO-6M
- Como programar o ESP8266 para calcular a distância entre a posição GPS atual e uma coordenada GPS predefinida (por exemplo, as coordenadas de Londres).
Além de longitude, latitude e altitude, o ESP8266 também consegue ler a velocidade GPS (km/h) e a data e hora de um módulo GPS NEO-6M.
Hardware Necessário
Or you can buy the following kits:
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgação: Alguns dos links desta seção são links de afiliado da Amazon. Podemos receber uma comissão pelas compras feitas por meio desses links, sem custo adicional para você. Agradecemos o seu apoio.
Sobre o módulo GPS NEO-6M
O módulo GPS NEO-6M é um módulo GPS que pode fornecer as seguintes informações:
- Longitude
- Latitude
- Altitude
- Velocidade GPS (km/h)
- Data e hora
Pinagem do Módulo GPS NEO-6M
O módulo GPS NEO-6M tem 4 pinos:
- Pino VCC: Deve ser conectado ao VCC (5V)
- Pino GND: Deve ser conectado ao GND (0V)
- Pino TX: Serve para a comunicação serial e deve ser conectado ao pino RX da Serial (ou SoftwareSerial) do ESP8266.
- Pino RX: Serve para a comunicação serial e deve ser conectado ao pino TX da Serial (ou SoftwareSerial) do ESP8266.
Diagrama de Ligação
This image is created using Fritzing. Click to enlarge image
Para mais informações, veja Pinagem do ESP8266 e como alimentar o ESP8266 e outros componentes.
Código ESP8266
Lendo as coordenadas GPS, a velocidade (km/h) e a data e hora
/*
* Este código de ESP8266 NodeMCU foi desenvolvido por pt.newbiely.com
* Este código de ESP8266 NodeMCU é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/esp8266/esp8266-gps
*/
#include <TinyGPS++.h>
#include <SoftwareSerial.h>
const int RX_PIN = 3, TX_PIN = 4;
const uint32_t GPS_BAUD = 9600; //Default baud of NEO-6M is 9600
TinyGPSPlus gps; // The TinyGPS++ object
SoftwareSerial gpsSerial(RX_PIN, TX_PIN); // The serial interface to the GPS device
void setup() {
Serial.begin(9600);
gpsSerial.begin(GPS_BAUD);
Serial.println(F("ESP8266 - GPS module"));
}
void loop() {
if (gpsSerial.available() > 0) {
if (gps.encode(gpsSerial.read())) {
if (gps.location.isValid()) {
Serial.print(F("- latitude: "));
Serial.println(gps.location.lat());
Serial.print(F("- longitude: "));
Serial.println(gps.location.lng());
Serial.print(F("- altitude: "));
if (gps.altitude.isValid())
Serial.println(gps.altitude.meters());
else
Serial.println(F("INVALID"));
} else {
Serial.println(F("- location: INVALID"));
}
Serial.print(F("- speed: "));
if (gps.speed.isValid()) {
Serial.print(gps.speed.kmph());
Serial.println(F(" km/h"));
} else {
Serial.println(F("INVALID"));
}
Serial.print(F("- GPS date&time: "));
if (gps.date.isValid() && gps.time.isValid()) {
Serial.print(gps.date.year());
Serial.print(F("-"));
Serial.print(gps.date.month());
Serial.print(F("-"));
Serial.print(gps.date.day());
Serial.print(F(" "));
Serial.print(gps.time.hour());
Serial.print(F(":"));
Serial.print(gps.time.minute());
Serial.print(F(":"));
Serial.println(gps.time.second());
} else {
Serial.println(F("INVALID"));
}
Serial.println();
}
}
if (millis() > 5000 && gps.charsProcessed() < 10)
Serial.println(F("No GPS data received: check wiring"));
}
Passos Rápidos
Para começar com o ESP8266 no Arduino IDE, siga estes passos:
- Confira o tutorial como configurar o ambiente para o ESP8266 no Arduino IDE se esta for a sua primeira vez usando o ESP8266.
- Ligue os componentes como mostrado no diagrama.
- Conecte a placa ESP8266 ao seu computador usando um cabo USB.
- Abra o Arduino IDE no seu computador.
- Escolha a placa ESP8266 correta, como (por exemplo, NodeMCU 1.0 (ESP-12E Module)), e a respectiva porta COM.
- Inicie o Arduino IDE
- Clique no ícone Libraries na barra esquerda do Arduino IDE.
- Pesquise “TinyGPSPlus” e encontre a biblioteca TinyGPSPlus de Mikal Hart
- Clique no botão Install para instalar a biblioteca TinyGPSPlus.
- Copie o código fornecido e abra-o no Arduino IDE.
- Clique no botão Upload no Arduino IDE para enviar o código ao ESP8266.
- Confira o resultado no Serial Monitor.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Nodemcu 1.0 (ESP-12E Module)' on 'COM15')
New Line
9600 baud
Calculando a distância da localização atual até uma localização predefinida
Este código calcula a distância entre a localização atual e Londres (latitude: 51.508131, longitude: -0.128002).
/*
* Este código de ESP8266 NodeMCU foi desenvolvido por pt.newbiely.com
* Este código de ESP8266 NodeMCU é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/esp8266/esp8266-gps
*/
#include <TinyGPS++.h>
#include <SoftwareSerial.h>
const int RX_PIN = 3, TX_PIN = 4;
const uint32_t GPS_BAUD = 9600; //Default baud of NEO-6M is 9600
TinyGPSPlus gps; // The TinyGPS++ object
SoftwareSerial gpsSerial(RX_PIN, TX_PIN); // The serial interface to the GPS device
const double LONDON_LAT = 51.508131;
const double LONDON_LON = -0.128002;
void setup() {
Serial.begin(9600);
gpsSerial.begin(GPS_BAUD);
Serial.println(F("ESP8266 - GPS module"));
}
void loop() {
if (gpsSerial.available() > 0) {
if (gps.encode(gpsSerial.read())) {
if (gps.location.isValid()) {
double latitude = gps.location.lat();
double longitude = gps.location.lng();
unsigned long distanceKm = TinyGPSPlus::distanceBetween(latitude, longitude, LONDON_LAT, LONDON_LON) / 1000;
Serial.print(F("- latitude: "));
Serial.println(latitude);
Serial.print(F("- longitude: "));
Serial.println(longitude);
Serial.print(F("- distance to London: "));
Serial.println(distanceKm);
} else {
Serial.println(F("- location: INVALID"));
}
Serial.println();
}
}
if (millis() > 5000 && gps.charsProcessed() < 10)
Serial.println(F("No GPS data received: check wiring"));
}
Passos Rápidos
- Ligue os componentes como mostrado no diagrama.
- Conecte a placa ESP8266 ao seu computador usando um cabo USB.
- Abra o Arduino IDE no seu computador.
- Escolha a placa ESP8266 correta, como (por exemplo, NodeMCU 1.0 (ESP-12E Module)), e a respectiva porta COM.
- Copie o código e abra-o no Arduino IDE.
- Clique no botão Upload no Arduino IDE para enviar o código ao ESP8266.
- Confira o resultado no Serial Monitor.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Nodemcu 1.0 (ESP-12E Module)' on 'COM15')
New Line
9600 baud