ESP8266 - Ethernet
Este guia mostra como conectar o ESP8266 à Internet ou à sua rede local usando o módulo Ethernet W5500. Veja o que vamos abordar:
- Conectando o ESP8266 ao Módulo Ethernet W5500
- Programando o ESP8266 para Requisições Web via Ethernet
- Criando um Servidor Web Básico no ESP8266 com Ethernet
Hardware Necessário
Or you can buy the following kits:
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgação: Alguns dos links desta seção são links de afiliado da Amazon. Podemos receber uma comissão pelas compras feitas por meio desses links, sem custo adicional para você. Agradecemos o seu apoio.
Sobre o módulo Ethernet W5500
O módulo Ethernet W5500 tem dois tipos de conexões:
- Interface RJ45: Conecte-a a um dispositivo de rede, como um roteador ou um switch, usando um cabo Ethernet.
- Interface SPI: Conecte-a a uma placa ESP8266 usando as seguintes conexões para seus 10 pinos:
- Pino NC: Deixe este pino desconectado.
- Pino INT: Deixe este pino desconectado.
- Pino RST: Conecte-o ao pino de reset (EN) do ESP8266.
- Pino GND: Conecte-o ao pino de terra (GND) do ESP8266.
- Pino 5V: Não conecte este pino.
- Pino 3.3V: Conecte-o ao pino 3.3V do ESP8266.
- Pino MISO: Conecte-o ao pino SPI MISO do ESP8266.
- Pino MOSFi: Conecte-o ao pino SPI MOSI do ESP8266.
- Pino SCS: Conecte-o ao pino SPI CS (Chip Select) do ESP8266.
- Pino SCLK: Conecte-o ao pino SPI SCK (Clock) do Arauthenticated.
image source: diyables.io
Diagrama de Ligação entre o ESP8266 e o módulo Ethernet W5500
This image is created using Fritzing. Click to enlarge image
Para mais informações, veja Pinagem do ESP8266 e como alimentar o ESP8266 e outros componentes.
image source: diyables.io
Código ESP8266 para o Módulo Ethernet - Fazendo uma requisição HTTP via Ethernet
Este código funciona como um cliente web. Ele envia requisições HTTP ao servidor web em http://example.com/.
/*
* Este código de ESP8266 NodeMCU foi desenvolvido por pt.newbiely.com
* Este código de ESP8266 NodeMCU é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/esp8266/esp8266-ethernet
*/
#include <SPI.h>
#include <Ethernet.h>
// replace the MAC address below by the MAC address printed on a sticker on the Arduino Shield 2
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xEF };
EthernetClient client;
int HTTP_PORT = 80;
String HTTP_METHOD = "GET"; // or POST
char HOST_NAME[] = "example.com";
String PATH_NAME = "/";
void setup() {
Serial.begin(9600);
delay(1000);
Serial.println("ESP8266 - Ethernet Tutorial");
// initialize the Ethernet shield using DHCP:
if (Ethernet.begin(mac) == 0) {
Serial.println("Failed to obtaining an IP address");
// check for Ethernet hardware present
if (Ethernet.hardwareStatus() == EthernetNoHardware)
Serial.println("Ethernet shield was not found");
// check for Ethernet cable
if (Ethernet.linkStatus() == LinkOFF)
Serial.println("Ethernet cable is not connected.");
while (true)
;
}
// connect to web server on port 80:
if (client.connect(HOST_NAME, HTTP_PORT)) {
// if connected:
Serial.println("Connected to server");
// make a HTTP request:
// send HTTP header
client.println(HTTP_METHOD + " " + PATH_NAME + " HTTP/1.1");
client.println("Host: " + String(HOST_NAME));
client.println("Connection: close");
client.println(); // end HTTP header
while (client.connected()) {
if (client.available()) {
// read an incoming byte from the server and print it to serial monitor:
char c = client.read();
Serial.print(c);
}
}
// the server's disconnected, stop the client:
client.stop();
Serial.println();
Serial.println("disconnected");
} else { // if not connected:
Serial.println("connection failed");
}
}
void loop() {
}
Passos Rápidos
Para começar com o ESP8266 no Arduino IDE, siga estes passos:
- Confira o tutorial como configurar o ambiente para o ESP8266 no Arduino IDE se for a primeira vez que você usa o ESP8266.
- Conecte o módulo Ethernet à placa ESP8266 conforme mostrado no diagrama de ligação.
- Use um cabo Ethernet para conectar o módulo Ethernet ao seu roteador ou switch.
- Conecte a placa ESP8266 ao seu computador usando um cabo USB.
- Abra o Arduino IDE no seu computador.
- Escolha a placa ESP8266 correta, como (por exemplo, NodeMCU 1.0 (ESP-12E Module)), e a respectiva porta COM.
- Clique no ícone Libraries na barra à esquerda do Arduino IDE.
- Pesquise Ethernet e encontre a biblioteca Ethernet de Various
- Clique no botão Install para instalar a biblioteca Ethernet.
- Abra o Serial Monitor no Arduino IDE.
- Copie o código fornecido e cole-o no Arduino IDE.
- Pressione o botão Upload no Arduino IDE para enviar o código ao ESP8266.
- Veja o resultado no Serial Monitor, que mostrará o resultado como abaixo.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Nodemcu 1.0 (ESP-12E Module)' on 'COM15')
New Line
9600 baud
ESP8266 - Ethernet Tutorial
Connected to server
HTTP/1.1 200 OK
Accept-Ranges: bytes
Age: 208425
Cache-Control: max-age=604800
Content-Type: text/html; charset=UTF-8
Date: Fri, 12 Jul 2024 07:08:42 GMT
Etag: "3147526947"
Expires: Fri, 19 Jul 2024 07:08:42 GMT
Last-Modified: Thu, 17 Oct 2019 07:18:26 GMT
Server: ECAcc (lac/55B8)
Vary: Accept-Encoding
X-Cache: HIT
Content-Length: 1256
Connection: close
<!doctype html>
<html>
<head>
<title>Example Domain</title>
<meta charset="utf-8" />
<meta http-equiv="Content-type" content="text/html; charset=utf-8" />
<meta name="viewport" content="width=device-width, initial-scale=1" />
</head>
<body>
<div>
<h1>Example Domain</h1>
<p>This domain is for use in illustrative examples in documents. You may use this
domain in literature without prior coordination or asking for permission.</p>
<p><a href="https://www.iana.org/domains/example">More information...</a></p>
</div>
</body>
</html>
disconnected
※ Nota:
Se outro dispositivo na mesma rede tiver o mesmo endereço MAC, ele pode não funcionar corretamente.
Código ESP8266 para o Módulo Ethernet - Servidor Web
O código abaixo transforma o ESP8266 em um servidor web. Esse servidor entrega uma página web básica aos navegadores da internet.
/*
* Este código de ESP8266 NodeMCU foi desenvolvido por pt.newbiely.com
* Este código de ESP8266 NodeMCU é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/esp8266/esp8266-ethernet
*/
#include <SPI.h>
#include <Ethernet.h>
// replace the MAC address below by the MAC address printed on a sticker on the Arduino Shield 2
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xEF };
EthernetServer server(80);
void setup() {
Serial.begin(9600);
delay(1000);
Serial.println("ESP8266 - Ethernet Tutorial");
// initialize the Ethernet shield using DHCP:
if (Ethernet.begin(mac) == 0) {
Serial.println("Failed to obtaining an IP address");
// check for Ethernet hardware present
if (Ethernet.hardwareStatus() == EthernetNoHardware)
Serial.println("Ethernet shield was not found");
// check for Ethernet cable
if (Ethernet.linkStatus() == LinkOFF)
Serial.println("Ethernet cable is not connected.");
while (true)
;
}
server.begin();
Serial.print("ESP8266 - Web Server IP Address: ");
Serial.println(Ethernet.localIP());
}
void loop() {
// listen for incoming clients
EthernetClient client = server.available();
if (client) {
Serial.println("new client");
// an HTTP request ends with a blank line
bool currentLineIsBlank = true;
while (client.connected()) {
if (client.available()) {
char c = client.read();
Serial.write(c);
// if you've gotten to the end of the line (received a newline
// character) and the line is blank, the HTTP request has ended,
// so you can send a reply
if (c == '\n' && currentLineIsBlank) {
// send a standard HTTP response header
client.println("HTTP/1.1 200 OK");
client.println("Content-Type: text/html");
client.println("Connection: close"); // the connection will be closed after completion of the response
client.println();
client.println("<!DOCTYPE HTML>");
client.println("<html>");
client.println("<body>");
client.println("<h1>ESP8266 - Web Server with Ethernet</h1>");
client.println("</body>");
client.println("</html>");
break;
}
if (c == '\n') {
// you're starting a new line
currentLineIsBlank = true;
} else if (c != '\r') {
// you've gotten a character on the current line
currentLineIsBlank = false;
}
}
}
// give the web browser time to receive the data
delay(1);
// close the connection:
client.stop();
Serial.println("client disconnected");
}
}
Passos Rápidos
- Copie o código acima e cole-o no Arduino IDE.
- Clique no botão Upload no Arduino IDE para transferir o código ao ESP8266.
- Veja os resultados no Serial Monitor; eles serão exibidos como descrito.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Nodemcu 1.0 (ESP-12E Module)' on 'COM15')
New Line
9600 baud
ESP8266 - Ethernet Tutorial
ESP8266 - Web Server IP Address: 192.168.0.2
- Copie o endereço IP fornecido acima e digite-o na barra de endereços do seu navegador web. Você verá uma página web simples exibida pelo ESP8266.
