ESP8266 - Gmail
Este guia vai mostrar como configurar um ESP8266 para enviar um e-mail pela sua conta do Gmail. O e-mail será enviado de uma conta do Gmail e pode ser recebido por qualquer conta de e-mail.
Hardware Necessário
Or you can buy the following kits:
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgação: Alguns dos links desta seção são links de afiliado da Amazon. Podemos receber uma comissão pelas compras feitas por meio desses links, sem custo adicional para você. Agradecemos o seu apoio.
Pré-Preparação
Para usar o código, você precisa de uma conta do Gmail e de uma senha de app especial. Estes são os detalhes principais para lembrar:
- Crie uma nova conta do Gmail só para testes, em vez de usar a sua conta de uso diário, para evitar problemas.
- A senha usada no código do ESP8266 não é a mesma senha da sua conta do Gmail. Você precisa obter uma "Senha de App" na sua Conta do Google seguindo algumas instruções.
Aqui estão os passos, um por um:
- Crie uma nova conta do Gmail.
- Entre na conta que você criou.
- Vá para a sua Conta do Google.
- Clique na seção "Segurança".
- Ative a Verificação em 2 Etapas (isso é essencial antes de usar senhas de app).
- Acesse o site Senhas de App do Google e crie uma senha de app. Você pode dar o nome que quiser.
- Clique no botão Criar e uma senha de 16 dígitos será exibida para você.
- Guarde este número de 16 dígitos. Você vai precisar dele no código do ESP8266 no próximo passo.
※ Nota:
A interface do usuário do Google pode mudar. Se você não vir "Senhas de App" depois de seguir os passos acima, pesquise por "How to get Google App Passwords" para encontrar instruções atualizadas.
Código ESP8266
/*
* Este código de ESP8266 NodeMCU foi desenvolvido por pt.newbiely.com
* Este código de ESP8266 NodeMCU é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/esp8266/esp8266-gmail
*/
#include <ESP8266WiFi.h>
#include <ESP_Mail_Client.h>
#define WIFI_SSID "YOUR_WIFI_SSID" // CHANGE IT
#define WIFI_PASSWORD "YOUR_WIFI_PASSWORD" // CHANGE IT
// the sender email credentials
#define SENDER_EMAIL "xxxxxx@gmail.com" // CHANGE IT
#define SENDER_PASSWORD "xxxx xxxx xxxx xxxx" // CHANGE IT to your Google App password
#define RECIPIENT_EMAIL "xxxxxx@gmail.com" // CHANGE IT
#define SMTP_HOST "smtp.gmail.com"
#define SMTP_PORT 587
SMTPSession smtp;
void setup() {
Serial.begin(9600);
WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
Serial.print("Connecting to Wi-Fi");
while (WiFi.status() != WL_CONNECTED) {
Serial.print(".");
delay(300);
}
Serial.println();
Serial.print("Connected with IP: ");
Serial.println(WiFi.localIP());
Serial.println();
String subject = "Email Notification from ESP8266";
String textMsg = "This is an email sent from ESP8266.\n";
textMsg += "Sensor value: ";
textMsg += "15"; // OR replace this value read from a sensor
gmail_send(subject, textMsg);
}
void loop() {
// YOUR OTHER CODE HERE
}
void gmail_send(String subject, String textMsg) {
// set the network reconnection option
MailClient.networkReconnect(true);
smtp.debug(1);
smtp.callback(smtpCallback);
Session_Config config;
// set the session config
config.server.host_name = SMTP_HOST;
config.server.port = SMTP_PORT;
config.login.email = SENDER_EMAIL;
config.login.password = SENDER_PASSWORD;
config.login.user_domain = F("127.0.0.1");
config.time.ntp_server = F("pool.ntp.org,time.nist.gov");
config.time.gmt_offset = 3;
config.time.day_light_offset = 0;
// declare the message class
SMTP_Message message;
// set the message headers
message.sender.name = F("ESP8266");
message.sender.email = SENDER_EMAIL;
message.subject = subject;
message.addRecipient(F("To Whom It May Concern"), RECIPIENT_EMAIL);
message.text.content = textMsg;
message.text.transfer_encoding = "base64";
message.text.charSet = F("utf-8");
message.priority = esp_mail_smtp_priority::esp_mail_smtp_priority_low;
// set the custom message header
message.addHeader(F("Message-ID: <abcde.fghij@gmail.com>"));
// connect to the server
if (!smtp.connect(&config)) {
Serial.printf("Connection error, Status Code: %d, Error Code: %d, Reason: %s\n", smtp.statusCode(), smtp.errorCode(), smtp.errorReason().c_str());
return;
}
if (!smtp.isLoggedIn()) {
Serial.println("Not yet logged in.");
} else {
if (smtp.isAuthenticated())
Serial.println("Successfully logged in.");
else
Serial.println("Connected with no Auth.");
}
// start sending Email and close the session
if (!MailClient.sendMail(&smtp, &message))
Serial.printf("Error, Status Code: %d, Error Code: %d, Reason: %s\n", smtp.statusCode(), smtp.errorCode(), smtp.errorReason().c_str());
}
// callback function to get the Email sending status
void smtpCallback(SMTP_Status status) {
// print the current status
Serial.println(status.info());
// print the sending result
if (status.success()) {
Serial.println("----------------");
Serial.printf("Message sent success: %d\n", status.completedCount());
Serial.printf("Message sent failed: %d\n", status.failedCount());
Serial.println("----------------\n");
for (size_t i = 0; i < smtp.sendingResult.size(); i++) {
// get the result item
SMTP_Result result = smtp.sendingResult.getItem(i);
Serial.printf("Message No: %d\n", i + 1);
Serial.printf("Status: %s\n", result.completed ? "success" : "failed");
Serial.printf("Date/Time: %s\n", MailClient.Time.getDateTimeString(result.timestamp, "%B %d, %Y %H:%M:%S").c_str());
Serial.printf("Recipient: %s\n", result.recipients.c_str());
Serial.printf("Subject: %s\n", result.subject.c_str());
}
Serial.println("----------------\n");
// free the memory
smtp.sendingResult.clear();
}
}
Passos Rápidos
Para começar com o ESP8266 na Arduino IDE, siga estes passos:
- Confira o tutorial como configurar o ambiente para ESP8266 na Arduino IDE se esta for a sua primeira vez usando o ESP8266.
- Ligue os componentes como mostrado no diagrama.
- Conecte a placa ESP8266 ao seu computador usando um cabo USB.
- Abra a Arduino IDE no seu computador.
- Escolha a placa ESP8266 correta, como (por exemplo, NodeMCU 1.0 (ESP-12E Module)), e sua respectiva porta COM.
- Clique no ícone Library Manager à esquerda na Arduino IDE.
- Pesquise por ESP Mail Client e escolha a biblioteca de Mobizt.
- Pressione o botão Install para adicionar a biblioteca ESP Mail Client.
- Copie o código acima e abra-o usando a Arduino IDE.
- Atualize as informações de WiFi alterando WIFI_SSID e WIFI_PASSWORD para o SSID e a senha da sua rede WiFi.
- Digite seu e-mail e sua senha no código, em SENDER_EMAIL e SENDER_PASSWORD.
- Atualize o endereço de e-mail do destinatário em RECIPIENT_EMAIL para o seu próprio e-mail, se necessário. Ele pode ser o mesmo e-mail do remetente.
※ Nota:
- O e-mail do remetente deve ser uma conta do Gmail.
- A senha do remetente é a Senha de App fornecida no passo anterior.
- O e-mail do destinatário pode ser de qualquer tipo.
- Clique no botão Upload na Arduino IDE para enviar o código ao ESP8266.
- Abra o Serial Monitor.
- Confira os resultados no Serial Monitor.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Nodemcu 1.0 (ESP-12E Module)' on 'COM15')
New Line
9600 baud
#### Message sent successfully
> C: message sent successfully
----------------
Message sent success: 1
Message sent failed: 0
----------------
Message No: 1
Status: success
Date/Time: May 27, 2024 04:42:50
Recipient: xxxxxx@gmail.com
Subject: Email Notification from ESP8266
----------------
- Olhe a caixa de entrada de e-mail da pessoa para quem você enviou o e-mail. Você vai encontrar um e-mail parecido com este:
