Arduino UNO R4 - Ethernet
Este guia mostra como conectar o Arduino UNO R4 à internet ou à sua rede local usando o módulo Ethernet W5500. Vamos abordar os seguintes detalhes:
- Como conectar o Arduino UNO R4 ao Módulo Ethernet W5500
- Como programar o Arduino UNO R4 para Fazer Requisições HTTP pela Ethernet
- Como criar um Servidor Web Básico no Arduino UNO R4 pela Ethernet
Hardware Necessário
Or you can buy the following kits:
| 1 | × | DIYables STEM V4 IoT Starter Kit (Arduino included) | |
| 1 | × | DIYables STEM V4B IoT Starter Kit (Arduino included) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgação: Alguns dos links desta seção são links de afiliado da Amazon. Podemos receber uma comissão pelas compras feitas por meio desses links, sem custo adicional para você. Agradecemos o seu apoio.
Sobre o módulo Ethernet W5500
O módulo Ethernet W5500 oferece duas interfaces:
- Interface Ethernet RJ45: Conecte a um roteador ou switch usando um cabo Ethernet.
- Interface SPI: Conecte a uma placa Arduino UNO R4 usando esta interface. Ela inclui 10 pinos:
- Pino NC: Deixe este pino desconectado.
- Pino INT: Deixe este pino desconectado.
- Pino RST: É o pino de reset. Conecte-o ao pino EN do Arduino UNO R4.
- Pino GND: Conecte este pino ao pino GND do Arduino UNO R4.
- Pino 5V: Conecte este pino ao pino 5V do Arduino UNO R4.
- Pino 3.3V: Deixe este pino desconectado.
- Pino MISO: Conecte este pino ao pino SPI MISO do Arduino UNO R4.
- Pino MOSI: Conecte este pino ao pino SPI MOSI do Arduino UNO R4.
- Pino SCS: Conecte este pino ao pino SPI CS do Arduino UNO R4.
- Pino SCLK: Conecte este pino ao pino SPI SCK do Arduino UNO R4.
image source: diyables.io
Diagrama de Ligação entre o Arduino UNO R4 e o módulo Ethernet W5500
This image is created using Fritzing. Click to enlarge image
Veja A melhor forma de alimentar o Arduino Uno R4 e outros componentes.
Código Arduino UNO R4 para o Módulo Ethernet - Fazendo requisição HTTP pela Ethernet
Este código funciona como um cliente web. Ele envia requisições HTTP ao servidor web em http://example.com/.
/*
* Este código de Arduino UNO R4 foi desenvolvido por pt.newbiely.com
* Este código de Arduino UNO R4 é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/arduino-uno-r4/arduino-uno-r4-ethernet-module
*/
#include <SPI.h>
#include <Ethernet.h>
// replace the MAC address below by the MAC address printed on a sticker on the Arduino Shield 2
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
EthernetClient client;
int HTTP_PORT = 80;
String HTTP_METHOD = "GET"; // or POST
char HOST_NAME[] = "example.com";
String PATH_NAME = "/";
void setup() {
Serial.begin(9600);
delay(1000);
Serial.println("Arduino Uno R4 - Ethernet Tutorial");
// initialize the Ethernet shield using DHCP:
if (Ethernet.begin(mac) == 0) {
Serial.println("Failed to obtaining an IP address");
// check for Ethernet hardware present
if (Ethernet.hardwareStatus() == EthernetNoHardware)
Serial.println("Ethernet shield was not found");
// check for Ethernet cable
if (Ethernet.linkStatus() == LinkOFF)
Serial.println("Ethernet cable is not connected.");
while (true)
;
}
// connect to web server on port 80:
if (client.connect(HOST_NAME, HTTP_PORT)) {
// if connected:
Serial.println("Connected to server");
// make a HTTP request:
// send HTTP header
client.println(HTTP_METHOD + " " + PATH_NAME + " HTTP/1.1");
client.println("Host: " + String(HOST_NAME));
client.println("Connection: close");
client.println(); // end HTTP header
while (client.connected()) {
if (client.available()) {
// read an incoming byte from the server and print it to serial monitor:
char c = client.read();
Serial.print(c);
}
}
// the server's disconnected, stop the client:
client.stop();
Serial.println();
Serial.println("disconnected");
} else { // if not connected:
Serial.println("connection failed");
}
}
void loop() {
}
Passos Rápidos
Siga estas instruções passo a passo:
- Se esta é a primeira vez que você usa o Arduino Uno R4 WiFi/Minima, consulte o tutorial sobre como configurar o ambiente para o Arduino Uno R4 WiFi/Minima no Arduino IDE.
- Conecte o módulo Ethernet ao seu Arduino UNO R4 de acordo com o diagrama fornecido
- Conecte o módulo Ethernet ao seu roteador ou switch usando um cabo Ethernet.
- Conecte a placa Arduino Uno R4 ao seu computador usando um cabo USB.
- Abra o Arduino IDE no seu computador.
- Selecione a placa Arduino Uno R4 apropriada (por exemplo, Arduino Uno R4 Minima) e a porta COM.
- Clique no ícone Libraries no lado esquerdo do Arduino IDE.
- Na caixa de pesquisa, digite “Ethernet” e localize a biblioteca Ethernet de Various.
- Pressione o botão Install para adicionar a biblioteca Ethernet.
- Abra o Serial Monitor no Arduino IDE.
- Copie o código fornecido e cole-o no Arduino IDE.
- Clique no botão Upload no Arduino IDE para enviar o código ao Arduino Uno R4.
- Para ver a saída, olhe o Serial Monitor, onde os resultados serão exibidos como indicado.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno R4 WiFi' on 'COM15')
New Line
9600 baud
Arduino UNO R4 - Ethernet Tutorial
Connected to server
HTTP/1.1 200 OK
Accept-Ranges: bytes
Age: 208425
Cache-Control: max-age=604800
Content-Type: text/html; charset=UTF-8
Date: Fri, 12 Jul 2024 07:08:42 GMT
Etag: "3147526947"
Expires: Fri, 19 Jul 2024 07:08:42 GMT
Last-Modified: Thu, 17 Oct 2019 07:18:26 GMT
Server: ECAcc (lac/55B8)
Vary: Accept-Encoding
X-Cache: HIT
Content-Length: 1256
Connection: close
<!doctype html>
<html>
<head>
<title>Example Domain</title>
<meta charset="utf-8" />
<meta http-equiv="Content-type" content="text/html; charset=utf-8" />
<meta name="viewport" content="width=device-width, initial-scale=1" />
</head>
<body>
<div>
<h1>Example Domain</h1>
<p>This domain is for use in illustrative examples in documents. You may use this
domain in literature without prior coordination or asking for permission.</p>
<p><a href="https://www.iana.org/domains/example">More information...</a></p>
</div>
</body>
</html>
disconnected
※ Nota:
Se outro dispositivo na mesma rede usar o mesmo endereço MAC que o seu, pode haver problemas.
Código Arduino UNO R4 para o Módulo Ethernet - Servidor Web
O código abaixo transforma o Arduino UNO R4 em um servidor web. Esse servidor envia uma página web simples aos navegadores da internet.
/*
* Este código de Arduino UNO R4 foi desenvolvido por pt.newbiely.com
* Este código de Arduino UNO R4 é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/arduino-uno-r4/arduino-uno-r4-ethernet-module
*/
#include <SPI.h>
#include <Ethernet.h>
// replace the MAC address below by the MAC address printed on a sticker on the Arduino Shield 2
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
EthernetServer server(80);
void setup() {
Serial.begin(9600);
delay(1000);
Serial.println("Arduino Uno R4 - Ethernet Tutorial");
// initialize the Ethernet shield using DHCP:
if (Ethernet.begin(mac) == 0) {
Serial.println("Failed to obtaining an IP address");
// check for Ethernet hardware present
if (Ethernet.hardwareStatus() == EthernetNoHardware)
Serial.println("Ethernet shield was not found");
// check for Ethernet cable
if (Ethernet.linkStatus() == LinkOFF)
Serial.println("Ethernet cable is not connected.");
while (true)
;
}
server.begin();
Serial.print("Arduino Uno R4 - Web Server IP Address: ");
Serial.println(Ethernet.localIP());
}
void loop() {
// listen for incoming clients
EthernetClient client = server.available();
if (client) {
Serial.println("new client");
// an HTTP request ends with a blank line
bool currentLineIsBlank = true;
while (client.connected()) {
if (client.available()) {
char c = client.read();
Serial.write(c);
// if you've gotten to the end of the line (received a newline
// character) and the line is blank, the HTTP request has ended,
// so you can send a reply
if (c == '\n' && currentLineIsBlank) {
// send a standard HTTP response header
client.println("HTTP/1.1 200 OK");
client.println("Content-Type: text/html");
client.println("Connection: close"); // the connection will be closed after completion of the response
client.println();
client.println("<!DOCTYPE HTML>");
client.println("<html>");
client.println("<body>");
client.println("<h1>Arduino Uno R4 - Web Server with Ethernet</h1>");
client.println("</body>");
client.println("</html>");
break;
}
if (c == '\n') {
// you're starting a new line
currentLineIsBlank = true;
} else if (c != '\r') {
// you've gotten a character on the current line
currentLineIsBlank = false;
}
}
}
// give the web browser time to receive the data
delay(1);
// close the connection:
client.stop();
Serial.println("client disconnected");
}
}
Passos Rápidos
- Copie o código acima e cole-o no Arduino IDE.
- Clique no botão Upload no Arduino IDE para fazer o upload do código para o Arduino Uno R4.
- Confira o resultado no Serial Monitor, que será exibido assim:
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno R4 WiFi' on 'COM15')
New Line
9600 baud
Arduino UNO R4 - Ethernet Tutorial
Arduino UNO R4 - Web Server IP Address: 192.168.0.2
- Copie o endereço IP mostrado acima e digite-o na barra de endereços do seu navegador. Você verá uma página web simples exibida pelo Arduino UNO R4.
