Arduino Nano - Joystick - Servo Motor
Este tutorial ensina você a usar o Arduino Nano e um joystick para controlar dois servo motores ou um kit pan-tilt.
Um joystick é equipado com dois potenciômetros perpendiculares entre si (conhecidos como eixo X e eixo Y). Esses potenciômetros fornecem valores analógicos (valor X e valor Y) nos pinos VRX e VRY. Vamos usar esses valores analógicos para controlar dois servo motores de forma independente: o valor X para o servo #1 e o valor Y para o servo #2. Ao usar um kit pan-tilt, o movimento dos dois servo motores cria um movimento 3-D.
Há dois casos de uso:
- Caso de uso 1: Os servo motores giram de acordo com o movimento do manche do joystick:
- Os ângulos dos servo motores são proporcionais aos valores X e Y do joystick.
- Quando o manche do joystick é solto, todos os valores voltam aos valores centrais e os servo motores voltam automaticamente à posição central
- Caso de uso 2: Use o joystick para comandar os servo motores (comandos de cima/baixo/esquerda/direita)
- Quando o manche do joystick é empurrado para a esquerda, o servo motor #1 se move no sentido horário
- Quando o manche do joystick é empurrado para a direita, o servo motor #1 se move no sentido anti-horário
- Quando o manche do joystick é empurrado para cima, o servo motor #2 se move no sentido horário
- Quando o manche do joystick é empurrado para baixo, o servo motor #2 se move no sentido anti-horário
- Quando o manche do joystick é solto, os servo motores não voltam à posição central
- Se o joystick for pressionado (botão de pressão), os servo motores voltam à posição central
- Conecte o cabo USB ao Arduino Nano e ao PC.
- Abra o Arduino IDE, escolha a placa e a porta corretas.
- Copie o código e abra-o no Arduino IDE.
- Clique no botão Upload no Arduino IDE para enviar o código ao Arduino Nano.
- Abra o Serial Monitor
- Empurre o joystick em uma determinada direção
- Veja a rotação do servo motor
- Veja o resultado no Serial Monitor
- Clique no ícone Libraries na barra esquerda do Arduino IDE.
- Pesquise por “ezButton” e localize a biblioteca de botão do ArduinoGetStarted.com.
- Pressione o botão Install para instalar a biblioteca ezButton.
- Copie o código e abra-o com o Arduino IDE.
- Clique no botão Upload na IDE para transferir o código para o Arduino Nano.
- Abra o Serial Monitor.
- Mova o joystick em uma determinada direção.
- Veja a rotação do servo motor.
- Veja o resultado no Serial Monitor.
O tutorial fornece o código para os dois cenários.
Hardware Necessário
Or you can buy the following kits:
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgação: Alguns dos links desta seção são links de afiliado da Amazon. Podemos receber uma comissão pelas compras feitas por meio desses links, sem custo adicional para você. Agradecemos o seu apoio.
Buy Note: For controlling multiple servo motors, use the PCA9685 16 Channel PWM Servo Driver Module to save MCU pins and simplify wiring.
Sobre o Joystick e o Servo Motor
Se você não está familiarizado com o joystick e o servo motor (incluindo pinagem, funcionamento, programação etc.), os tutoriais a seguir podem ajudar:
Diagrama de Ligação
This image is created using Fritzing. Click to enlarge image
Veja A melhor forma de alimentar o Arduino Nano e outros componentes.
Não se esqueça de conectar o GND da alimentação externa ao GND do Arduino Nano.
Código Arduino Nano
Código Arduino Nano - Os servo motores giram de acordo com o movimento do manche do joystick
/*
* Este código de Arduino Nano foi desenvolvido por pt.newbiely.com
* Este código de Arduino Nano é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/arduino-nano/arduino-nano-joystick-servo-motor
*/
#include <Servo.h>
#define VRX_PIN A6 // The Arduino Nano pin connected to VRX pin
#define VRY_PIN A7 // The Arduino Nano pin connected to VRY pin
#define SERVO_X_PIN 6 // The Arduino Nano pin connected to Servo motor 1
#define SERVO_Y_PIN 11 // The Arduino Nano pin connected to Servo motor 2
Servo servo_X; // create servo object to control a servo 1
Servo servo_Y; // create servo object to control a servo 2
void setup() {
Serial.begin(9600) ;
servo_X.attach(SERVO_X_PIN);
servo_Y.attach(SERVO_Y_PIN);
}
void loop() {
// read analog X and Y analog values
int value_X = analogRead(VRX_PIN);
int value_Y = analogRead(VRY_PIN);
int xAngle = map(value_X, 0, 1023, 0, 180); // scale it to the servo's angle (0 to 180)
int yAngle = map(value_Y, 0, 1023, 0, 180); // scale it to the servo's angle (0 to 180)
servo_X.write(xAngle); // rotate servo motor 1
servo_Y.write(yAngle); // rotate servo motor 2
// print data to Serial Monitor on Arduino IDE
Serial.print("Joystick: ");
Serial.print(value_X);
Serial.print(", ");
Serial.print(value_Y);
Serial.print(" => Servo Motor: ");
Serial.print(xAngle);
Serial.print("°, ");
Serial.print(yAngle);
Serial.println("°");
}
Passos Rápidos
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Nano' on 'COM15')
New Line
9600 baud
Coming soon
Código Arduino Nano - Use o joystick para comandar os servo motores
/*
* Este código de Arduino Nano foi desenvolvido por pt.newbiely.com
* Este código de Arduino Nano é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/arduino-nano/arduino-nano-joystick-servo-motor
*/
#include <Servo.h>
#include <ezButton.h>
#define VRX_PIN A6 // The Arduino Nano pin connected to VRX pin
#define VRY_PIN A7 // The Arduino Nano pin connected to VRY pin
#define SW_PIN 2 // The Arduino Nano pin connected to SW pin
#define SERVO_X_PIN 6 // The Arduino Nano pin connected to Servo motor 1
#define SERVO_Y_PIN 11 // The Arduino Nano pin connected to Servo motor 2
#define COMMAND_NO 0x00
#define COMMAND_LEFT 0x01
#define COMMAND_RIGHT 0x02
#define COMMAND_UP 0x04
#define COMMAND_DOWN 0x08
#define LEFT_THRESHOLD 400
#define RIGHT_THRESHOLD 800
#define UP_THRESHOLD 400
#define DOWN_THRESHOLD 800
#define UPDATE_INTERVAL 100 // 100ms
ezButton button(SW_PIN);
Servo servo_X; // create servo object to control a servo 1
Servo servo_Y; // create servo object to control a servo 2
int value_X = 0 ; // The variable to store value of the X axis
int value_Y = 0 ; // The variable to store value of the Y axis
int xAngle = 90; // The center position of servo #1
int yAngle = 90; // The center position of servo #2
int command = COMMAND_NO;
unsigned long lastUpdateTime = 0;
void setup() {
Serial.begin(9600) ;
servo_X.attach(SERVO_X_PIN);
servo_Y.attach(SERVO_Y_PIN);
button.setDebounceTime(50); // set debounce time to 50 milliseconds
}
void loop() {
button.loop(); // MUST call the loop() function first
if (millis() - lastUpdateTime > UPDATE_INTERVAL) {
lastUpdateTime = millis() ;
// read analog X and Y analog values
value_X = analogRead(VRX_PIN);
value_Y = analogRead(VRY_PIN);
// converts the analog value to commands
// reset commands
command = COMMAND_NO;
// check left/right commands
if (value_X < LEFT_THRESHOLD)
command = command | COMMAND_LEFT;
else if (value_X > RIGHT_THRESHOLD)
command = command | COMMAND_RIGHT;
// check up/down commands
if (value_Y < UP_THRESHOLD)
command = command | COMMAND_UP;
else if (value_Y > DOWN_THRESHOLD)
command = command | COMMAND_DOWN;
// NOTE: AT A TIME, THERE MAY BE NO COMMAND, ONE COMMAND OR TWO COMMANDS
// print command to serial and process command
if (command & COMMAND_LEFT) {
Serial.println("COMMAND LEFT");
xAngle--;
}
if (command & COMMAND_RIGHT) {
Serial.println("COMMAND RIGHT");
xAngle++;
}
if (command & COMMAND_UP) {
Serial.println("COMMAND UP");
yAngle--;
}
if (command & COMMAND_DOWN) {
Serial.println("COMMAND DOWN");
yAngle++;
}
}
if (button.isPressed()) {
Serial.println("The button is pressed");
xAngle = 90; // The center position of servo #1
yAngle = 90; // The center position of servo #2
}
servo_X.write(xAngle); // rotate servo motor 1
servo_Y.write(yAngle); // rotate servo motor 2
// print data to Serial Monitor on Arduino IDE
Serial.print("Servo Motor's Angle: ");
Serial.print(xAngle);
Serial.print("°, ");
Serial.print(xAngle);
Serial.println("°");
}
Passos Rápidos
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Nano' on 'COM15')
New Line
9600 baud
Explicação do Código
Confira a explicação linha por linha nos comentários do código-fonte!