Arduino Nano ESP32 - Encoder Rotativo
Neste guia, você vai aprender a usar o encoder rotativo com um Arduino Nano ESP32. Veja o que vamos aprender:
- Quais são as diferenças entre um encoder rotativo e um potenciômetro
- Como o encoder rotativo funciona
- Como conectar o encoder rotativo ao Arduino Nano ESP32
- Como escrever o código para o Arduino Nano ESP32 ler a direção e a posição do encoder rotativo SEM interrupção.
- Como escrever o código para o Arduino Nano ESP32 ler a direção e a posição do encoder rotativo COM interrupção.
Hardware Necessário
Or you can buy the following kits:
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Divulgação: Alguns dos links desta seção são links de afiliado da Amazon. Podemos receber uma comissão pelas compras feitas por meio desses links, sem custo adicional para você. Agradecemos o seu apoio.
Sobre o Encoder Rotativo
Um botão giratório, como o de um rádio, pode enviar sinais que viram eletricidade. Ele nos ajuda a saber quanto ele girou e em que posição está. Existem dois tipos principais:
- Encoder incremental: este usa sinais rápidos para medir quanto algo mudou de posição.
- Encoder absoluto: este tipo fornece um código secreto para cada posição, o que nos ajuda a encontrar onde algo está, mesmo que a energia seja cortada.
Esta lição é principalmente sobre o primeiro tipo, o encoder incremental.
Pinagem do Módulo Encoder Rotativo
Um módulo encoder rotativo tem 4 pinos:
- Pino CLK (Saída A): é o pulso principal que nos diz quanta rotação ocorreu. Sempre que você gira o botão por um detent (clique) em qualquer direção, o pino CLK emite um sinal que completa um ciclo inteiro (LOW → HIGH → LOW).
- Pino DT (Saída B): age como o pino CLK, mas emite um sinal que fica atrasado 90 graus em relação ao sinal CLK. Ele nos ajuda a descobrir a direção da rotação (sentido horário ou anti-horário).
- Pino SW: vem do botão do encoder. Ele é normalmente aberto. Quando adicionamos um resistor pull-up a este pino, o pino SW fica HIGH quando o botão não está pressionado e LOW quando está pressionado.
- Pino VCC (+): precisa ser conectado ao VCC (entre 3,3 e 5 volts)
- Pino GND: precisa ser conectado ao GND (0V)
Encoder Rotativo vs Potenciômetro
Você pode confundir o encoder rotativo com o potenciômetro. mas eles são componentes diferentes. Veja uma comparação entre eles:
- O encoder rotativo é como a versão moderna do potenciômetro, mas pode fazer mais coisas.
- O encoder rotativo pode girar um círculo completo sem parar, enquanto o potenciômetro só pode girar cerca de três quartos do círculo.
- O encoder rotativo emite pulsos, enquanto o potenciômetro emite a tensão analógica.
- O encoder rotativo é útil quando você só precisa saber quanto o botão se moveu, não exatamente onde ele está. O potenciômetro é útil quando você realmente precisa saber exatamente onde o botão está.
Como o Encoder Rotativo Funciona
Dentro do encoder, há um pequeno disco com ranhuras conectado a um pino chamado C, que age como um terra compartilhado. Há mais dois pinos, A e B.
- Quando você gira o botão, os pinos A e B tocam o pino de terra compartilhado C, mas a ordem em que eles o tocam depende do sentido em que você está girando o botão (horário ou anti-horário).
- Esses toques criam dois sinais. Eles são um pouco diferentes no tempo, porque um pino toca o terra antes do outro. Esses sinais estão defasados em 90 graus, o que é chamado de codificação em quadratura.
- Se você girar o botão no sentido horário, o pino A toca o terra antes do pino B. Mas se você girar no sentido anti-horário, o pino B toca o terra primeiro, antes do pino A.
- Verificando quando cada pino toca ou deixa o terra, podemos descobrir para que lado o botão está girando. Fazemos isso verificando o que acontece com o pino B quando o pino A muda.
Quando A muda de estado de LOW para HIGH:
- Se B está HIGH, o botão foi girado no sentido anti-horário.
- Se B está LOW, o botão foi girado no sentido horário.
※ Nota:
Os pinos A e B estão conectados aos pinos CLK e DT. No entanto, dependendo dos fabricantes, a ordem pode ser diferente. Os códigos fornecidos abaixo foram testados com o encoder rotativo da DIYables
Como Programar para o Encoder Rotativo
- O Arduino Nano ESP32 lê o sinal do pino CLK
- Se o estado mudar de LOW para HIGH, então o Arduino Nano ESP32 lê o estado do pino DT.
- Se o pino DT estiver HIGH, o botão foi girado no sentido anti-horário, e o Arduino Nano ESP32 aumenta o contador em 1
- Se o pino DT estiver LOW, o botão foi girado no sentido horário, e o Arduino Nano ESP32 diminui o contador em 1
Diagrama de Ligação
This image is created using Fritzing. Click to enlarge image
Código Arduino Nano ESP32 – Encoder Rotativo
O código Arduino Nano ESP32 abaixo faz o seguinte:
- Detecta a direção e a quantidade de rotação do encoder.
- Se detectar o botão girado por um detent (clique) no sentido horário, aumenta o contador em um.
- Se detectar o botão girado por um detent (clique) no sentido anti-horário, diminui o contador em um.
- Detecta se o botão foi pressionado.
/*
* Este código de Arduino Nano ESP32 foi desenvolvido por pt.newbiely.com
* Este código de Arduino Nano ESP32 é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/arduino-nano-esp32/arduino-nano-esp32-rotary-encoder
*/
#include <ezButton.h> // The library to use for SW pin
#define CLK_PIN D2 // The Arduino Nano ESP32 pin D2 connected to the rotary encoder's CLK pin
#define DT_PIN D3 // The Arduino Nano ESP32 pin D3 connected to the rotary encoder's DT pin
#define SW_PIN D4 // The Arduino Nano ESP32 pin D4 connected to the rotary encoder's SW pin
#define DIRECTION_CW 0 // clockwise direction
#define DIRECTION_CCW 1 // counter-clockwise direction
int counter = 0;
int direction = DIRECTION_CW;
int CLK_state;
int prev_CLK_state;
ezButton button(SW_PIN); // create ezButton object for pin 7;
void setup() {
Serial.begin(9600);
// Configure encoder pins as inputs
pinMode(CLK_PIN, INPUT);
pinMode(DT_PIN, INPUT);
button.setDebounceTime(50); // set debounce time to 50 milliseconds
// read the initial state of the rotary encoder's CLK pin
prev_CLK_state = digitalRead(CLK_PIN);
}
void loop() {
button.loop(); // MUST call the loop() function first
// read the current state of the rotary encoder's CLK pin
CLK_state = digitalRead(CLK_PIN);
// If the state of CLK is changed, then pulse occurred
// React to only the rising edge (from LOW to HIGH) to avoid double count
if (CLK_state != prev_CLK_state && CLK_state == HIGH) {
// if the DT state is HIGH
// The encoder is rotating in counter-clockwise direction => decrease the counter
if (digitalRead(DT_PIN) == HIGH) {
counter--;
direction = DIRECTION_CCW;
} else {
// The encoder is rotating in clockwise direction => increase the counter
counter++;
direction = DIRECTION_CW;
}
Serial.print("Rotary Encoder:: direction: ");
if (direction == DIRECTION_CW)
Serial.print("Clockwise");
else
Serial.print("Counter-clockwise");
Serial.print(" - count: ");
Serial.println(counter);
}
// save last CLK state
prev_CLK_state = CLK_state;
if (button.isPressed()) {
Serial.println("The button is pressed");
}
}
Para simplificar o código de debounce do botão, a biblioteca ezButton é usada.
Passos Rápidos
Se esta é a primeira vez que você usa o Arduino Nano ESP32, veja como configurar o ambiente para o Arduino Nano ESP32 no Arduino IDE.
- Instale a biblioteca ezButton no Arduino IDE.
- Copie o código acima e abra com o Arduino IDE
- Clique no botão Upload no Arduino IDE para fazer upload do código para o Arduino Nano ESP32
- Gire o botão no sentido horário e depois no sentido anti-horário
- Pressione o botão
- Veja o resultado no Serial Monitor.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Nano ESP32' on 'COM15')
New Line
9600 baud
Rotary Encoder:: direction: CLOCKWISE - count: 1
Rotary Encoder:: direction: CLOCKWISE - count: 2
Rotary Encoder:: direction: CLOCKWISE - count: 3
Rotary Encoder:: direction: CLOCKWISE - count: 4
Rotary Encoder:: direction: CLOCKWISE - count: 5
Rotary Encoder:: direction: ANTICLOCKWISE - count: 4
Rotary Encoder:: direction: ANTICLOCKWISE - count: 3
Rotary Encoder:: direction: ANTICLOCKWISE - count: 2
Rotary Encoder:: direction: ANTICLOCKWISE - count: 1
Rotary Encoder:: direction: ANTICLOCKWISE - count: 0
The button is pressed
Explicação do Código
Veja os comentários linha por linha no código
Código Arduino Nano ESP32 – Encoder Rotativo com Interrupção
No código anterior, usar polling para verificar continuamente o estado do pino pode desperdiçar recursos do Arduino Nano ESP32 e levar a contagens perdidas se a execução de outro código for lenta.
Uma solução eficaz é utilizar a interrupção, que elimina a necessidade de polling. Isso permite que o Arduino Nano ESP32 execute outras tarefas sem perder as contagens. Abaixo está o código Arduino Nano ESP32 que usa a interrupção para ler a direção e a posição do encoder rotativo.
/*
* Este código de Arduino Nano ESP32 foi desenvolvido por pt.newbiely.com
* Este código de Arduino Nano ESP32 é disponibilizado ao público sem nenhuma restrição.
* Para tutoriais completos e diagramas de ligação, visite:
* https://pt.newbiely.com/tutorials/arduino-nano-esp32/arduino-nano-esp32-rotary-encoder
*/
#include <ezButton.h> // The library to use for SW pin
#define CLK_PIN D2 // The Arduino Nano ESP32 pin D2 connected to the rotary encoder's CLK pin
#define DT_PIN D3 // The Arduino Nano ESP32 pin D3 connected to the rotary encoder's DT pin
#define SW_PIN D4 // The Arduino Nano ESP32 pin D4 connected to the rotary encoder's SW pin
#define DIRECTION_CW 0 // clockwise direction
#define DIRECTION_CCW 1 // counter-clockwise direction
volatile int counter = 0;
volatile int direction = DIRECTION_CW;
volatile unsigned long last_time; // for debouncing
int prev_counter;
ezButton button(SW_PIN); // create ezButton object for pin 7;
void IRAM_ATTR ISR_encoder() {
if ((millis() - last_time) < 50) // debounce time is 50ms
return;
if (digitalRead(DT_PIN) == HIGH) {
// The encoder is rotating in counter-clockwise direction => decrease the counter
counter--;
direction = DIRECTION_CCW;
} else {
// The encoder is rotating in clockwise direction => increase the counter
counter++;
direction = DIRECTION_CW;
}
last_time = millis();
}
void setup() {
Serial.begin(9600);
// Configure encoder pins as inputs
pinMode(CLK_PIN, INPUT);
pinMode(DT_PIN, INPUT);
button.setDebounceTime(50); // set debounce time to 50 milliseconds
// use interrupt for CLK pin is enough
// call ISR_encoder() when CLK pin changes from LOW to HIGH
attachInterrupt(digitalPinToInterrupt(CLK_PIN), ISR_encoder, RISING);
}
void loop() {
button.loop(); // MUST call the loop() function first
if (prev_counter != counter) {
Serial.print("Rotary Encoder:: direction: ");
if (direction == DIRECTION_CW)
Serial.print("CLOCKWISE");
else
Serial.print("ANTICLOCKWISE");
Serial.print(" - count: ");
Serial.println(counter);
prev_counter = counter;
}
if (button.isPressed()) {
Serial.println("The button is pressed");
}
// TO DO: your other work here
}
Agora, ao girar o botão, você verá informações aparecendo no Serial Monitor, bem parecidas com as que você viu no código anterior.
※ Nota:
- Você pode encontrar tutoriais em outros sites que usam duas interrupções para um único encoder, mas isso é desnecessário e um desperdício. Apenas uma interrupção é suficiente.
- É importante usar a palavra-chave volatile para as variáveis globais usadas na interrupção. Ignorar isso pode causar problemas inesperados.
- Mantenha o código dentro da interrupção o mais simples possível. Evite usar Serial.print() ou Serial.println() dentro da interrupção.
Aplicação do Encoder Rotativo com Arduino Nano ESP32
Com o Encoder Rotativo, podemos fazer as seguintes aplicações, mas sem se limitar a elas:
- Arduino Nano ESP32 - Encoder Rotativo controla a Posição do Servo Motor
- Arduino Nano ESP32 - Encoder Rotativo controla o Brilho do LED
- Arduino Nano ESP32 - Encoder Rotativo controla a Velocidade do Motor de Passo